scripts/headers_install.pl

   1 #!/usr/bin/perl -w
   2 #
   3 # headers_install prepare the listed header files for use in
   4 # user space and copy the files to their destination.
   5 #
   6 # Usage: headers_install.pl readdir installdir arch [files...]
   7 # readdir:    dir to open files
   8 # installdir: dir to install the files
   9 # arch:       current architecture
  10 #             arch is used to force a reinstallation when the arch
  11 #             changes because kbuild then detect a command line change.
  12 # files:      list of files to check
  13 #
  14 # Step in preparation for users space:
  15 # 1) Drop all use of compiler.h definitions
  16 # 2) Drop include of compiler.h
  17 # 3) Drop all sections defined out by __KERNEL__ (using unifdef)
  18
  19 use strict;
  20
  21 my ($readdir, $installdir, $arch, $printdir, @files) = @ARGV;
  22
  23 $printdir =~ s@^include/@@;
  24
  25 my $unifdef = "scripts/unifdef -U__KERNEL__ -D__EXPORTED_HEADERS__";
  26
  27 foreach my $file (@files) {
  28         my $tmpfile = "$installdir/$file.tmp";
  29
  30         open(my $in, '<', "$readdir/$file")
  31             or die "$readdir/$file: $!\n";
  32         open(my $out, '>', $tmpfile)
  33             or die "$tmpfile: $!\n";
  34         while (my $line = <$in>) {
  35                 # Any #include which uses "" and does not have a path needs
  36                 # rewriting so that the resultant user space headers are
  37                 # safe against the use of -I-.
  38                 $line =~ s/^(\s*#\s*include\s+)"([^\/]*?)"/$1<$printdir\/$2>/;
  39                 $line =~ s/([\s(])__user\s/$1/g;
  40                 $line =~ s/([\s(])__force\s/$1/g;
  41                 $line =~ s/([\s(])__iomem\s/$1/g;
  42                 $line =~ s/\s__attribute_const__\s/ /g;
  43                 $line =~ s/\s__attribute_const__$//g;
  44                 $line =~ s/\b__packed\b/__attribute__((packed))/g;
  45                 $line =~ s/^#include <linux\/compiler.h>//;
  46                 $line =~ s/(^|\s)(inline)\b/$1__$2__/g;
  47                 $line =~ s/(^|\s)(asm)\b(\s|[(]|$)/$1__$2__$3/g;
  48                 $line =~ s/(^|\s|[(])(volatile)\b(\s|[(]|$)/$1__$2__$3/g;
  49                 printf {$out} "%s", $line;
  50         }
  51         close $out;
  52         close $in;
  53
  54         system $unifdef . " $tmpfile > $installdir/$file";
  55         # unifdef will exit 0 on success, and will exit 1 when the
  56         # file was processed successfully but no changes were made,
  57         # so abort only when it's higher than that.
  58         my $e = $? >> 8;
  59         if ($e > 1) {
  60                 die "$tmpfile: $!\n";
  61         }
  62         unlink $tmpfile;
  63 }
  64 exit 0;