arch/x86_64/ia32/vsyscall.lds

   1 /*
   2  * Linker script for vsyscall DSO.  The vsyscall page is an ELF shared
   3  * object prelinked to its virtual address. This script controls its layout.
   4  */
   5
   6 /* This must match <asm/fixmap.h>.  */
   7 VSYSCALL_BASE = 0xffffe000;
   8
   9 SECTIONS
  10 {
  11   . = VSYSCALL_BASE + SIZEOF_HEADERS;
  12
  13   .hash           : { *(.hash) }                :text
  14   .dynsym         : { *(.dynsym) }
  15   .dynstr         : { *(.dynstr) }
  16   .gnu.version    : { *(.gnu.version) }
  17   .gnu.version_d  : { *(.gnu.version_d) }
  18   .gnu.version_r  : { *(.gnu.version_r) }
  19
  20   /* This linker script is used both with -r and with -shared.
  21      For the layouts to match, we need to skip more than enough
  22      space for the dynamic symbol table et al.  If this amount
  23      is insufficient, ld -shared will barf.  Just increase it here.  */
  24   . = VSYSCALL_BASE + 0x400;
  25
  26   .text.vsyscall   : { *(.text.vsyscall) }      :text =0x90909090
  27
  28   /* This is an 32bit object and we cannot easily get the offsets
  29      into the 64bit kernel. Just hardcode them here. This assumes
  30      that all the stubs don't need more than 0x100 bytes. */
  31   . = VSYSCALL_BASE + 0x500;
  32
  33   .text.sigreturn  : { *(.text.sigreturn) }     :text =0x90909090
  34
  35   . = VSYSCALL_BASE + 0x600;
  36
  37   .text.rtsigreturn : { *(.text.rtsigreturn) }   :text =0x90909090
  38
  39   .eh_frame_hdr   : { *(.eh_frame_hdr) }        :text :eh_frame_hdr
  40   .eh_frame       : { KEEP (*(.eh_frame)) }     :text
  41   .dynamic        : { *(.dynamic) }             :text :dynamic
  42   .useless        : {
  43         *(.got.plt) *(.got)
  44         *(.data .data.* .gnu.linkonce.d.*)
  45         *(.dynbss)
  46         *(.bss .bss.* .gnu.linkonce.b.*)
  47   }                                             :text
  48 }
  49
  50 /*
  51  * We must supply the ELF program headers explicitly to get just one
  52  * PT_LOAD segment, and set the flags explicitly to make segments read-only.
  53  */
  54 PHDRS
  55 {
  56   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  57   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  58   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  59 }
  60
  61 /*
  62  * This controls what symbols we export from the DSO.
  63  */
  64 VERSION
  65 {
  66   LINUX_2.5 {
  67     global:
  68         __kernel_vsyscall;
  69         __kernel_sigreturn;
  70         __kernel_rt_sigreturn;
  71
  72     local: *;
  73   };
  74 }
  75
  76 /* The ELF entry point can be used to set the AT_SYSINFO value.  */
  77 ENTRY(__kernel_vsyscall);