arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <linux/err.h>
  59
  60 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  61 #include <linux/elf-em.h>
  62 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  63 #define __AUDIT_ARCH_64BIT 0x80000000
  64 #define __AUDIT_ARCH_LE    0x40000000
  65
  66         .code64
  67         .section .entry.text, "ax"
  68
  69 #ifdef CONFIG_FUNCTION_TRACER
  70 #ifdef CONFIG_DYNAMIC_FTRACE
  71 ENTRY(mcount)
  72         retq
  73 END(mcount)
  74
  75 ENTRY(ftrace_caller)
  76         cmpl $0, function_trace_stop
  77         jne  ftrace_stub
  78
  79         MCOUNT_SAVE_FRAME
  80
  81         movq 0x38(%rsp), %rdi
  82         movq 8(%rbp), %rsi
  83         subq $MCOUNT_INSN_SIZE, %rdi
  84
  85 GLOBAL(ftrace_call)
  86         call ftrace_stub
  87
  88         MCOUNT_RESTORE_FRAME
  89
  90 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
  91 GLOBAL(ftrace_graph_call)
  92         jmp ftrace_stub
  93 #endif
  94
  95 GLOBAL(ftrace_stub)
  96         retq
  97 END(ftrace_caller)
  98
  99 #else /* ! CONFIG_DYNAMIC_FTRACE */
 100 ENTRY(mcount)
 101         cmpl $0, function_trace_stop
 102         jne  ftrace_stub
 103
 104         cmpq $ftrace_stub, ftrace_trace_function
 105         jnz trace
 106
 107 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 108         cmpq $ftrace_stub, ftrace_graph_return
 109         jnz ftrace_graph_caller
 110
 111         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 112         jnz ftrace_graph_caller
 113 #endif
 114
 115 GLOBAL(ftrace_stub)
 116         retq
 117
 118 trace:
 119         MCOUNT_SAVE_FRAME
 120
 121         movq 0x38(%rsp), %rdi
 122         movq 8(%rbp), %rsi
 123         subq $MCOUNT_INSN_SIZE, %rdi
 124
 125         call   *ftrace_trace_function
 126
 127         MCOUNT_RESTORE_FRAME
 128
 129         jmp ftrace_stub
 130 END(mcount)
 131 #endif /* CONFIG_DYNAMIC_FTRACE */
 132 #endif /* CONFIG_FUNCTION_TRACER */
 133
 134 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 135 ENTRY(ftrace_graph_caller)
 136         cmpl $0, function_trace_stop
 137         jne ftrace_stub
 138
 139         MCOUNT_SAVE_FRAME
 140
 141         leaq 8(%rbp), %rdi
 142         movq 0x38(%rsp), %rsi
 143         movq (%rbp), %rdx
 144         subq $MCOUNT_INSN_SIZE, %rsi
 145
 146         call    prepare_ftrace_return
 147
 148         MCOUNT_RESTORE_FRAME
 149
 150         retq
 151 END(ftrace_graph_caller)
 152
 153 GLOBAL(return_to_handler)
 154         subq  $24, %rsp
 155
 156         /* Save the return values */
 157         movq %rax, (%rsp)
 158         movq %rdx, 8(%rsp)
 159         movq %rbp, %rdi
 160
 161         call ftrace_return_to_handler
 162
 163         movq %rax, %rdi
 164         movq 8(%rsp), %rdx
 165         movq (%rsp), %rax
 166         addq $24, %rsp
 167         jmp *%rdi
 168 #endif
 169
 170
 171 #ifndef CONFIG_PREEMPT
 172 #define retint_kernel retint_restore_args
 173 #endif
 174
 175 #ifdef CONFIG_PARAVIRT
 176 ENTRY(native_usergs_sysret64)
 177         swapgs
 178         sysretq
 179 ENDPROC(native_usergs_sysret64)
 180 #endif /* CONFIG_PARAVIRT */
 181
 182
 183 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 184 #ifdef CONFIG_TRACE_IRQFLAGS
 185         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 186         jnc  1f
 187         TRACE_IRQS_ON
 188 1:
 189 #endif
 190 .endm
 191
 192 /*
 193  * C code is not supposed to know about undefined top of stack. Every time
 194  * a C function with an pt_regs argument is called from the SYSCALL based
 195  * fast path FIXUP_TOP_OF_STACK is needed.
 196  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 197  * manipulation.
 198  */
 199
 200         /* %rsp:at FRAMEEND */
 201         .macro FIXUP_TOP_OF_STACK tmp offset=0
 202         movq PER_CPU_VAR(old_rsp),\tmp
 203         movq \tmp,RSP+\offset(%rsp)
 204         movq $__USER_DS,SS+\offset(%rsp)
 205         movq $__USER_CS,CS+\offset(%rsp)
 206         movq $-1,RCX+\offset(%rsp)
 207         movq R11+\offset(%rsp),\tmp  /* get eflags */
 208         movq \tmp,EFLAGS+\offset(%rsp)
 209         .endm
 210
 211         .macro RESTORE_TOP_OF_STACK tmp offset=0
 212         movq RSP+\offset(%rsp),\tmp
 213         movq \tmp,PER_CPU_VAR(old_rsp)
 214         movq EFLAGS+\offset(%rsp),\tmp
 215         movq \tmp,R11+\offset(%rsp)
 216         .endm
 217
 218         .macro FAKE_STACK_FRAME child_rip
 219         /* push in order ss, rsp, eflags, cs, rip */
 220         xorl %eax, %eax
 221         pushq_cfi $__KERNEL_DS /* ss */
 222         /*CFI_REL_OFFSET        ss,0*/
 223         pushq_cfi %rax /* rsp */
 224         CFI_REL_OFFSET  rsp,0
 225         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
 226         /*CFI_REL_OFFSET        rflags,0*/
 227         pushq_cfi $__KERNEL_CS /* cs */
 228         /*CFI_REL_OFFSET        cs,0*/
 229         pushq_cfi \child_rip /* rip */
 230         CFI_REL_OFFSET  rip,0
 231         pushq_cfi %rax /* orig rax */
 232         .endm
 233
 234         .macro UNFAKE_STACK_FRAME
 235         addq $8*6, %rsp
 236         CFI_ADJUST_CFA_OFFSET   -(6*8)
 237         .endm
 238
 239 /*
 240  * initial frame state for interrupts (and exceptions without error code)
 241  */
 242         .macro EMPTY_FRAME offset=0
 243         CFI_STARTPROC simple
 244         CFI_SIGNAL_FRAME
 245         CFI_DEF_CFA rsp,\offset
 246         .endm
 247
 248 /*
 249  * initial frame state for interrupts (and exceptions without error code)
 250  */
 251         .macro INTR_FRAME start=1 offset=0
 252         .if \start
 253         EMPTY_FRAME SS+8+\offset-RIP
 254         .else
 255         CFI_DEF_CFA_OFFSET SS+8+\offset-RIP
 256         .endif
 257         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 258         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 259         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 260         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 261         CFI_REL_OFFSET rip, RIP+\offset-RIP
 262         .endm
 263
 264 /*
 265  * initial frame state for exceptions with error code (and interrupts
 266  * with vector already pushed)
 267  */
 268         .macro XCPT_FRAME start=1 offset=0
 269         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 270         .endm
 271
 272 /*
 273  * frame that enables calling into C.
 274  */
 275         .macro PARTIAL_FRAME start=1 offset=0
 276         .if \start >= 0
 277         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 278         .endif
 279         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 280         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 281         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 282         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 283         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 284         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 285         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 286         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 287         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 288         .endm
 289
 290 /*
 291  * frame that enables passing a complete pt_regs to a C function.
 292  */
 293         .macro DEFAULT_FRAME start=1 offset=0
 294         .if \start >= -1
 295         PARTIAL_FRAME \start, R11+\offset-R15
 296         .endif
 297         CFI_REL_OFFSET rbx, RBX+\offset
 298         CFI_REL_OFFSET rbp, RBP+\offset
 299         CFI_REL_OFFSET r12, R12+\offset
 300         CFI_REL_OFFSET r13, R13+\offset
 301         CFI_REL_OFFSET r14, R14+\offset
 302         CFI_REL_OFFSET r15, R15+\offset
 303         .endm
 304
 305 /* save partial stack frame */
 306         .macro SAVE_ARGS_IRQ
 307         cld
 308         /* start from rbp in pt_regs and jump over */
 309         movq_cfi rdi, RDI-RBP
 310         movq_cfi rsi, RSI-RBP
 311         movq_cfi rdx, RDX-RBP
 312         movq_cfi rcx, RCX-RBP
 313         movq_cfi rax, RAX-RBP
 314         movq_cfi  r8,  R8-RBP
 315         movq_cfi  r9,  R9-RBP
 316         movq_cfi r10, R10-RBP
 317         movq_cfi r11, R11-RBP
 318
 319         /* Save rbp so that we can unwind from get_irq_regs() */
 320         movq_cfi rbp, 0
 321
 322         /* Save previous stack value */
 323         movq %rsp, %rsi
 324
 325         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 326         testl $3, CS(%rdi)
 327         je 1f
 328         SWAPGS
 329         /*
 330          * irq_count is used to check if a CPU is already on an interrupt stack
 331          * or not. While this is essentially redundant with preempt_count it is
 332          * a little cheaper to use a separate counter in the PDA (short of
 333          * moving irq_enter into assembly, which would be too much work)
 334          */
 335 1:      incl PER_CPU_VAR(irq_count)
 336         jne 2f
 337         mov PER_CPU_VAR(irq_stack_ptr),%rsp
 338         CFI_DEF_CFA_REGISTER    rsi
 339
 340 2:      /* Store previous stack value */
 341         pushq %rsi
 342         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 343                         0x77 /* DW_OP_breg7 */, 0, \
 344                         0x06 /* DW_OP_deref */, \
 345                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 346                         0x22 /* DW_OP_plus */
 347         /* We entered an interrupt context - irqs are off: */
 348         TRACE_IRQS_OFF
 349         .endm
 350
 351 ENTRY(save_rest)
 352         CFI_STARTPROC
 353         movq 5*8+16(%rsp), %r11 /* save return address */
 354         movq %rbx, RBX+16(%rsp)
 355         movq %rbp, RBP+16(%rsp)
 356         movq %r12, R12+16(%rsp)
 357         movq %r13, R13+16(%rsp)
 358         movq %r14, R14+16(%rsp)
 359         movq %r15, R15+16(%rsp)
 360         movq %r11, 8(%rsp)      /* return address */
 361         FIXUP_TOP_OF_STACK %r11, 16
 362         ret
 363         CFI_ENDPROC
 364 END(save_rest)
 365
 366 /* save complete stack frame */
 367         .pushsection .kprobes.text, "ax"
 368 ENTRY(save_paranoid)
 369         XCPT_FRAME offset=ORIG_RAX-R15+8
 370         cld
 371         movq %rdi, RDI+8(%rsp)
 372         movq %rsi, RSI+8(%rsp)
 373         movq_cfi rdx, RDX+8
 374         movq_cfi rcx, RCX+8
 375         movq_cfi rax, RAX+8
 376         movq %r8, R8+8(%rsp)
 377         movq %r9, R9+8(%rsp)
 378         movq %r10, R10+8(%rsp)
 379         movq %r11, R11+8(%rsp)
 380         movq_cfi rbx, RBX+8
 381         movq %rbp, RBP+8(%rsp)
 382         movq %r12, R12+8(%rsp)
 383         movq %r13, R13+8(%rsp)
 384         movq %r14, R14+8(%rsp)
 385         movq %r15, R15+8(%rsp)
 386         movl $1,%ebx
 387         movl $MSR_GS_BASE,%ecx
 388         rdmsr
 389         testl %edx,%edx
 390         js 1f   /* negative -> in kernel */
 391         SWAPGS
 392         xorl %ebx,%ebx
 393 1:      ret
 394         CFI_ENDPROC
 395 END(save_paranoid)
 396         .popsection
 397
 398 /*
 399  * A newly forked process directly context switches into this address.
 400  *
 401  * rdi: prev task we switched from
 402  */
 403 ENTRY(ret_from_fork)
 404         DEFAULT_FRAME
 405
 406         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 407
 408         pushq_cfi kernel_eflags(%rip)
 409         popfq_cfi                               # reset kernel eflags
 410
 411         call schedule_tail                      # rdi: 'prev' task parameter
 412
 413         GET_THREAD_INFO(%rcx)
 414
 415         RESTORE_REST
 416
 417         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 418         jz   retint_restore_args
 419
 420         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 421         jnz  int_ret_from_sys_call
 422
 423         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 424         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 425
 426         CFI_ENDPROC
 427 END(ret_from_fork)
 428
 429 /*
 430  * System call entry. Up to 6 arguments in registers are supported.
 431  *
 432  * SYSCALL does not save anything on the stack and does not change the
 433  * stack pointer.
 434  */
 435
 436 /*
 437  * Register setup:
 438  * rax  system call number
 439  * rdi  arg0
 440  * rcx  return address for syscall/sysret, C arg3
 441  * rsi  arg1
 442  * rdx  arg2
 443  * r10  arg3    (--> moved to rcx for C)
 444  * r8   arg4
 445  * r9   arg5
 446  * r11  eflags for syscall/sysret, temporary for C
 447  * r12-r15,rbp,rbx saved by C code, not touched.
 448  *
 449  * Interrupts are off on entry.
 450  * Only called from user space.
 451  *
 452  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 453  *      and report it properly in ps. Unfortunately we haven't.
 454  *
 455  * When user can change the frames always force IRET. That is because
 456  * it deals with uncanonical addresses better. SYSRET has trouble
 457  * with them due to bugs in both AMD and Intel CPUs.
 458  */
 459
 460 ENTRY(system_call)
 461         CFI_STARTPROC   simple
 462         CFI_SIGNAL_FRAME
 463         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 464         CFI_REGISTER    rip,rcx
 465         /*CFI_REGISTER  rflags,r11*/
 466         SWAPGS_UNSAFE_STACK
 467         /*
 468          * A hypervisor implementation might want to use a label
 469          * after the swapgs, so that it can do the swapgs
 470          * for the guest and jump here on syscall.
 471          */
 472 GLOBAL(system_call_after_swapgs)
 473
 474         movq    %rsp,PER_CPU_VAR(old_rsp)
 475         movq    PER_CPU_VAR(kernel_stack),%rsp
 476         /*
 477          * No need to follow this irqs off/on section - it's straight
 478          * and short:
 479          */
 480         ENABLE_INTERRUPTS(CLBR_NONE)
 481         SAVE_ARGS 8,0
 482         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 483         movq  %rcx,RIP-ARGOFFSET(%rsp)
 484         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 485         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 486         jnz tracesys
 487 system_call_fastpath:
 488         cmpq $__NR_syscall_max,%rax
 489         ja badsys
 490         movq %r10,%rcx
 491         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 492         movq %rax,RAX-ARGOFFSET(%rsp)
 493 /*
 494  * Syscall return path ending with SYSRET (fast path)
 495  * Has incomplete stack frame and undefined top of stack.
 496  */
 497 ret_from_sys_call:
 498         movl $_TIF_ALLWORK_MASK,%edi
 499         /* edi: flagmask */
 500 sysret_check:
 501         LOCKDEP_SYS_EXIT
 502         DISABLE_INTERRUPTS(CLBR_NONE)
 503         TRACE_IRQS_OFF
 504         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 505         andl %edi,%edx
 506         jnz  sysret_careful
 507         CFI_REMEMBER_STATE
 508         /*
 509          * sysretq will re-enable interrupts:
 510          */
 511         TRACE_IRQS_ON
 512         movq RIP-ARGOFFSET(%rsp),%rcx
 513         CFI_REGISTER    rip,rcx
 514         RESTORE_ARGS 1,-ARG_SKIP,0
 515         /*CFI_REGISTER  rflags,r11*/
 516         movq    PER_CPU_VAR(old_rsp), %rsp
 517         USERGS_SYSRET64
 518
 519         CFI_RESTORE_STATE
 520         /* Handle reschedules */
 521         /* edx: work, edi: workmask */
 522 sysret_careful:
 523         bt $TIF_NEED_RESCHED,%edx
 524         jnc sysret_signal
 525         TRACE_IRQS_ON
 526         ENABLE_INTERRUPTS(CLBR_NONE)
 527         pushq_cfi %rdi
 528         call schedule
 529         popq_cfi %rdi
 530         jmp sysret_check
 531
 532         /* Handle a signal */
 533 sysret_signal:
 534         TRACE_IRQS_ON
 535         ENABLE_INTERRUPTS(CLBR_NONE)
 536 #ifdef CONFIG_AUDITSYSCALL
 537         bt $TIF_SYSCALL_AUDIT,%edx
 538         jc sysret_audit
 539 #endif
 540         /*
 541          * We have a signal, or exit tracing or single-step.
 542          * These all wind up with the iret return path anyway,
 543          * so just join that path right now.
 544          */
 545         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 546         jmp int_check_syscall_exit_work
 547
 548 badsys:
 549         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 550         jmp ret_from_sys_call
 551
 552 #ifdef CONFIG_AUDITSYSCALL
 553         /*
 554          * Fast path for syscall audit without full syscall trace.
 555          * We just call __audit_syscall_entry() directly, and then
 556          * jump back to the normal fast path.
 557          */
 558 auditsys:
 559         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 560         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 561         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 562         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 563         movq %rax,%rsi                  /* 2nd arg: syscall number */
 564         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 565         call __audit_syscall_entry
 566         LOAD_ARGS 0             /* reload call-clobbered registers */
 567         jmp system_call_fastpath
 568
 569         /*
 570          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 571          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 572          * masked off.
 573          */
 574 sysret_audit:
 575         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 576         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 577         setbe %al               /* 1 if so, 0 if not */
 578         movzbl %al,%edi         /* zero-extend that into %edi */
 579         call __audit_syscall_exit
 580         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 581         jmp sysret_check
 582 #endif  /* CONFIG_AUDITSYSCALL */
 583
 584         /* Do syscall tracing */
 585 tracesys:
 586 #ifdef CONFIG_AUDITSYSCALL
 587         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 588         jz auditsys
 589 #endif
 590         SAVE_REST
 591         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 592         FIXUP_TOP_OF_STACK %rdi
 593         movq %rsp,%rdi
 594         call syscall_trace_enter
 595         /*
 596          * Reload arg registers from stack in case ptrace changed them.
 597          * We don't reload %rax because syscall_trace_enter() returned
 598          * the value it wants us to use in the table lookup.
 599          */
 600         LOAD_ARGS ARGOFFSET, 1
 601         RESTORE_REST
 602         cmpq $__NR_syscall_max,%rax
 603         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 604         movq %r10,%rcx  /* fixup for C */
 605         call *sys_call_table(,%rax,8)
 606         movq %rax,RAX-ARGOFFSET(%rsp)
 607         /* Use IRET because user could have changed frame */
 608
 609 /*
 610  * Syscall return path ending with IRET.
 611  * Has correct top of stack, but partial stack frame.
 612  */
 613 GLOBAL(int_ret_from_sys_call)
 614         DISABLE_INTERRUPTS(CLBR_NONE)
 615         TRACE_IRQS_OFF
 616         movl $_TIF_ALLWORK_MASK,%edi
 617         /* edi: mask to check */
 618 GLOBAL(int_with_check)
 619         LOCKDEP_SYS_EXIT_IRQ
 620         GET_THREAD_INFO(%rcx)
 621         movl TI_flags(%rcx),%edx
 622         andl %edi,%edx
 623         jnz   int_careful
 624         andl    $~TS_COMPAT,TI_status(%rcx)
 625         jmp   retint_swapgs
 626
 627         /* Either reschedule or signal or syscall exit tracking needed. */
 628         /* First do a reschedule test. */
 629         /* edx: work, edi: workmask */
 630 int_careful:
 631         bt $TIF_NEED_RESCHED,%edx
 632         jnc  int_very_careful
 633         TRACE_IRQS_ON
 634         ENABLE_INTERRUPTS(CLBR_NONE)
 635         pushq_cfi %rdi
 636         call schedule
 637         popq_cfi %rdi
 638         DISABLE_INTERRUPTS(CLBR_NONE)
 639         TRACE_IRQS_OFF
 640         jmp int_with_check
 641
 642         /* handle signals and tracing -- both require a full stack frame */
 643 int_very_careful:
 644         TRACE_IRQS_ON
 645         ENABLE_INTERRUPTS(CLBR_NONE)
 646 int_check_syscall_exit_work:
 647         SAVE_REST
 648         /* Check for syscall exit trace */
 649         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 650         jz int_signal
 651         pushq_cfi %rdi
 652         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 653         call syscall_trace_leave
 654         popq_cfi %rdi
 655         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 656         jmp int_restore_rest
 657
 658 int_signal:
 659         testl $_TIF_DO_NOTIFY_MASK,%edx
 660         jz 1f
 661         movq %rsp,%rdi          # &ptregs -> arg1
 662         xorl %esi,%esi          # oldset -> arg2
 663         call do_notify_resume
 664 1:      movl $_TIF_WORK_MASK,%edi
 665 int_restore_rest:
 666         RESTORE_REST
 667         DISABLE_INTERRUPTS(CLBR_NONE)
 668         TRACE_IRQS_OFF
 669         jmp int_with_check
 670         CFI_ENDPROC
 671 END(system_call)
 672
 673 /*
 674  * Certain special system calls that need to save a complete full stack frame.
 675  */
 676         .macro PTREGSCALL label,func,arg
 677 ENTRY(\label)
 678         PARTIAL_FRAME 1 8               /* offset 8: return address */
 679         subq $REST_SKIP, %rsp
 680         CFI_ADJUST_CFA_OFFSET REST_SKIP
 681         call save_rest
 682         DEFAULT_FRAME -2 8              /* offset 8: return address */
 683         leaq 8(%rsp), \arg      /* pt_regs pointer */
 684         call \func
 685         jmp ptregscall_common
 686         CFI_ENDPROC
 687 END(\label)
 688         .endm
 689
 690         PTREGSCALL stub_clone, sys_clone, %r8
 691         PTREGSCALL stub_fork, sys_fork, %rdi
 692         PTREGSCALL stub_vfork, sys_vfork, %rdi
 693         PTREGSCALL stub_sigaltstack, sys_sigaltstack, %rdx
 694         PTREGSCALL stub_iopl, sys_iopl, %rsi
 695
 696 ENTRY(ptregscall_common)
 697         DEFAULT_FRAME 1 8       /* offset 8: return address */
 698         RESTORE_TOP_OF_STACK %r11, 8
 699         movq_cfi_restore R15+8, r15
 700         movq_cfi_restore R14+8, r14
 701         movq_cfi_restore R13+8, r13
 702         movq_cfi_restore R12+8, r12
 703         movq_cfi_restore RBP+8, rbp
 704         movq_cfi_restore RBX+8, rbx
 705         ret $REST_SKIP          /* pop extended registers */
 706         CFI_ENDPROC
 707 END(ptregscall_common)
 708
 709 ENTRY(stub_execve)
 710         CFI_STARTPROC
 711         addq $8, %rsp
 712         PARTIAL_FRAME 0
 713         SAVE_REST
 714         FIXUP_TOP_OF_STACK %r11
 715         movq %rsp, %rcx
 716         call sys_execve
 717         RESTORE_TOP_OF_STACK %r11
 718         movq %rax,RAX(%rsp)
 719         RESTORE_REST
 720         jmp int_ret_from_sys_call
 721         CFI_ENDPROC
 722 END(stub_execve)
 723
 724 /*
 725  * sigreturn is special because it needs to restore all registers on return.
 726  * This cannot be done with SYSRET, so use the IRET return path instead.
 727  */
 728 ENTRY(stub_rt_sigreturn)
 729         CFI_STARTPROC
 730         addq $8, %rsp
 731         PARTIAL_FRAME 0
 732         SAVE_REST
 733         movq %rsp,%rdi
 734         FIXUP_TOP_OF_STACK %r11
 735         call sys_rt_sigreturn
 736         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 737         RESTORE_REST
 738         jmp int_ret_from_sys_call
 739         CFI_ENDPROC
 740 END(stub_rt_sigreturn)
 741
 742 /*
 743  * Build the entry stubs and pointer table with some assembler magic.
 744  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 745  * single cache line on all modern x86 implementations.
 746  */
 747         .section .init.rodata,"a"
 748 ENTRY(interrupt)
 749         .section .entry.text
 750         .p2align 5
 751         .p2align CONFIG_X86_L1_CACHE_SHIFT
 752 ENTRY(irq_entries_start)
 753         INTR_FRAME
 754 vector=FIRST_EXTERNAL_VECTOR
 755 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 756         .balign 32
 757   .rept 7
 758     .if vector < NR_VECTORS
 759       .if vector <> FIRST_EXTERNAL_VECTOR
 760         CFI_ADJUST_CFA_OFFSET -8
 761       .endif
 762 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 763       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 764         jmp 2f
 765       .endif
 766       .previous
 767         .quad 1b
 768       .section .entry.text
 769 vector=vector+1
 770     .endif
 771   .endr
 772 2:      jmp common_interrupt
 773 .endr
 774         CFI_ENDPROC
 775 END(irq_entries_start)
 776
 777 .previous
 778 END(interrupt)
 779 .previous
 780
 781 /*
 782  * Interrupt entry/exit.
 783  *
 784  * Interrupt entry points save only callee clobbered registers in fast path.
 785  *
 786  * Entry runs with interrupts off.
 787  */
 788
 789 /* 0(%rsp): ~(interrupt number) */
 790         .macro interrupt func
 791         /* reserve pt_regs for scratch regs and rbp */
 792         subq $ORIG_RAX-RBP, %rsp
 793         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 794         SAVE_ARGS_IRQ
 795         call \func
 796         .endm
 797
 798 /*
 799  * Interrupt entry/exit should be protected against kprobes
 800  */
 801         .pushsection .kprobes.text, "ax"
 802         /*
 803          * The interrupt stubs push (~vector+0x80) onto the stack and
 804          * then jump to common_interrupt.
 805          */
 806         .p2align CONFIG_X86_L1_CACHE_SHIFT
 807 common_interrupt:
 808         XCPT_FRAME
 809         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
 810         interrupt do_IRQ
 811         /* 0(%rsp): old_rsp-ARGOFFSET */
 812 ret_from_intr:
 813         DISABLE_INTERRUPTS(CLBR_NONE)
 814         TRACE_IRQS_OFF
 815         decl PER_CPU_VAR(irq_count)
 816
 817         /* Restore saved previous stack */
 818         popq %rsi
 819         CFI_DEF_CFA_REGISTER    rsi
 820         leaq ARGOFFSET-RBP(%rsi), %rsp
 821         CFI_DEF_CFA_REGISTER    rsp
 822         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
 823
 824 exit_intr:
 825         GET_THREAD_INFO(%rcx)
 826         testl $3,CS-ARGOFFSET(%rsp)
 827         je retint_kernel
 828
 829         /* Interrupt came from user space */
 830         /*
 831          * Has a correct top of stack, but a partial stack frame
 832          * %rcx: thread info. Interrupts off.
 833          */
 834 retint_with_reschedule:
 835         movl $_TIF_WORK_MASK,%edi
 836 retint_check:
 837         LOCKDEP_SYS_EXIT_IRQ
 838         movl TI_flags(%rcx),%edx
 839         andl %edi,%edx
 840         CFI_REMEMBER_STATE
 841         jnz  retint_careful
 842
 843 retint_swapgs:          /* return to user-space */
 844         /*
 845          * The iretq could re-enable interrupts:
 846          */
 847         DISABLE_INTERRUPTS(CLBR_ANY)
 848         TRACE_IRQS_IRETQ
 849         SWAPGS
 850         jmp restore_args
 851
 852 retint_restore_args:    /* return to kernel space */
 853         DISABLE_INTERRUPTS(CLBR_ANY)
 854         /*
 855          * The iretq could re-enable interrupts:
 856          */
 857         TRACE_IRQS_IRETQ
 858 restore_args:
 859         RESTORE_ARGS 1,8,1
 860
 861 irq_return:
 862         INTERRUPT_RETURN
 863
 864         .section __ex_table, "a"
 865         .quad irq_return, bad_iret
 866         .previous
 867
 868 #ifdef CONFIG_PARAVIRT
 869 ENTRY(native_iret)
 870         iretq
 871
 872         .section __ex_table,"a"
 873         .quad native_iret, bad_iret
 874         .previous
 875 #endif
 876
 877         .section .fixup,"ax"
 878 bad_iret:
 879         /*
 880          * The iret traps when the %cs or %ss being restored is bogus.
 881          * We've lost the original trap vector and error code.
 882          * #GPF is the most likely one to get for an invalid selector.
 883          * So pretend we completed the iret and took the #GPF in user mode.
 884          *
 885          * We are now running with the kernel GS after exception recovery.
 886          * But error_entry expects us to have user GS to match the user %cs,
 887          * so swap back.
 888          */
 889         pushq $0
 890
 891         SWAPGS
 892         jmp general_protection
 893
 894         .previous
 895
 896         /* edi: workmask, edx: work */
 897 retint_careful:
 898         CFI_RESTORE_STATE
 899         bt    $TIF_NEED_RESCHED,%edx
 900         jnc   retint_signal
 901         TRACE_IRQS_ON
 902         ENABLE_INTERRUPTS(CLBR_NONE)
 903         pushq_cfi %rdi
 904         call  schedule
 905         popq_cfi %rdi
 906         GET_THREAD_INFO(%rcx)
 907         DISABLE_INTERRUPTS(CLBR_NONE)
 908         TRACE_IRQS_OFF
 909         jmp retint_check
 910
 911 retint_signal:
 912         testl $_TIF_DO_NOTIFY_MASK,%edx
 913         jz    retint_swapgs
 914         TRACE_IRQS_ON
 915         ENABLE_INTERRUPTS(CLBR_NONE)
 916         SAVE_REST
 917         movq $-1,ORIG_RAX(%rsp)
 918         xorl %esi,%esi          # oldset
 919         movq %rsp,%rdi          # &pt_regs
 920         call do_notify_resume
 921         RESTORE_REST
 922         DISABLE_INTERRUPTS(CLBR_NONE)
 923         TRACE_IRQS_OFF
 924         GET_THREAD_INFO(%rcx)
 925         jmp retint_with_reschedule
 926
 927 #ifdef CONFIG_PREEMPT
 928         /* Returning to kernel space. Check if we need preemption */
 929         /* rcx:  threadinfo. interrupts off. */
 930 ENTRY(retint_kernel)
 931         cmpl $0,TI_preempt_count(%rcx)
 932         jnz  retint_restore_args
 933         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
 934         jnc  retint_restore_args
 935         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
 936         jnc  retint_restore_args
 937         call preempt_schedule_irq
 938         jmp exit_intr
 939 #endif
 940
 941         CFI_ENDPROC
 942 END(common_interrupt)
 943 /*
 944  * End of kprobes section
 945  */
 946        .popsection
 947
 948 /*
 949  * APIC interrupts.
 950  */
 951 .macro apicinterrupt num sym do_sym
 952 ENTRY(\sym)
 953         INTR_FRAME
 954         pushq_cfi $~(\num)
 955 .Lcommon_\sym:
 956         interrupt \do_sym
 957         jmp ret_from_intr
 958         CFI_ENDPROC
 959 END(\sym)
 960 .endm
 961
 962 #ifdef CONFIG_SMP
 963 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
 964         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
 965 apicinterrupt REBOOT_VECTOR \
 966         reboot_interrupt smp_reboot_interrupt
 967 #endif
 968
 969 #ifdef CONFIG_X86_UV
 970 apicinterrupt UV_BAU_MESSAGE \
 971         uv_bau_message_intr1 uv_bau_message_interrupt
 972 #endif
 973 apicinterrupt LOCAL_TIMER_VECTOR \
 974         apic_timer_interrupt smp_apic_timer_interrupt
 975 apicinterrupt X86_PLATFORM_IPI_VECTOR \
 976         x86_platform_ipi smp_x86_platform_ipi
 977
 978 #ifdef CONFIG_SMP
 979         ALIGN
 980         INTR_FRAME
 981 .irp idx,1,2,3,4,5,6,7,8,9,10,11,12,13,14,15, \
 982         16,17,18,19,20,21,22,23,24,25,26,27,28,29,30,31
 983 .if NUM_INVALIDATE_TLB_VECTORS > \idx
 984 ENTRY(invalidate_interrupt\idx)
 985         pushq_cfi $~(INVALIDATE_TLB_VECTOR_START+\idx)
 986         jmp .Lcommon_invalidate_interrupt0
 987         CFI_ADJUST_CFA_OFFSET -8
 988 END(invalidate_interrupt\idx)
 989 .endif
 990 .endr
 991         CFI_ENDPROC
 992 apicinterrupt INVALIDATE_TLB_VECTOR_START, \
 993         invalidate_interrupt0, smp_invalidate_interrupt
 994 #endif
 995
 996 apicinterrupt THRESHOLD_APIC_VECTOR \
 997         threshold_interrupt smp_threshold_interrupt
 998 apicinterrupt THERMAL_APIC_VECTOR \
 999         thermal_interrupt smp_thermal_interrupt
1000
1001 #ifdef CONFIG_SMP
1002 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1003         call_function_single_interrupt smp_call_function_single_interrupt
1004 apicinterrupt CALL_FUNCTION_VECTOR \
1005         call_function_interrupt smp_call_function_interrupt
1006 apicinterrupt RESCHEDULE_VECTOR \
1007         reschedule_interrupt smp_reschedule_interrupt
1008 #endif
1009
1010 apicinterrupt ERROR_APIC_VECTOR \
1011         error_interrupt smp_error_interrupt
1012 apicinterrupt SPURIOUS_APIC_VECTOR \
1013         spurious_interrupt smp_spurious_interrupt
1014
1015 #ifdef CONFIG_IRQ_WORK
1016 apicinterrupt IRQ_WORK_VECTOR \
1017         irq_work_interrupt smp_irq_work_interrupt
1018 #endif
1019
1020 /*
1021  * Exception entry points.
1022  */
1023 .macro zeroentry sym do_sym
1024 ENTRY(\sym)
1025         INTR_FRAME
1026         PARAVIRT_ADJUST_EXCEPTION_FRAME
1027         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1028         subq $ORIG_RAX-R15, %rsp
1029         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1030         call error_entry
1031         DEFAULT_FRAME -1
1032         movq %rsp,%rdi          /* pt_regs pointer */
1033         xorl %esi,%esi          /* no error code */
1034         call \do_sym
1035         jmp error_exit          /* %ebx: no swapgs flag */
1036         CFI_ENDPROC
1037 END(\sym)
1038 .endm
1039
1040 .macro paranoidzeroentry sym do_sym
1041 ENTRY(\sym)
1042         INTR_FRAME
1043         PARAVIRT_ADJUST_EXCEPTION_FRAME
1044         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1045         subq $ORIG_RAX-R15, %rsp
1046         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1047         call save_paranoid
1048         DEFAULT_FRAME -1
1049         TRACE_IRQS_OFF
1050         movq %rsp,%rdi          /* pt_regs pointer */
1051         xorl %esi,%esi          /* no error code */
1052         call \do_sym
1053         jmp paranoid_exit       /* %ebx: no swapgs flag */
1054         CFI_ENDPROC
1055 END(\sym)
1056 .endm
1057
1058 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1059 .macro paranoidzeroentry_ist sym do_sym ist
1060 ENTRY(\sym)
1061         INTR_FRAME
1062         PARAVIRT_ADJUST_EXCEPTION_FRAME
1063         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1064         subq $ORIG_RAX-R15, %rsp
1065         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1066         call save_paranoid
1067         DEFAULT_FRAME -1
1068         TRACE_IRQS_OFF
1069         movq %rsp,%rdi          /* pt_regs pointer */
1070         xorl %esi,%esi          /* no error code */
1071         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1072         call \do_sym
1073         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1074         jmp paranoid_exit       /* %ebx: no swapgs flag */
1075         CFI_ENDPROC
1076 END(\sym)
1077 .endm
1078
1079 .macro errorentry sym do_sym
1080 ENTRY(\sym)
1081         XCPT_FRAME
1082         PARAVIRT_ADJUST_EXCEPTION_FRAME
1083         subq $ORIG_RAX-R15, %rsp
1084         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1085         call error_entry
1086         DEFAULT_FRAME -1
1087         movq %rsp,%rdi                  /* pt_regs pointer */
1088         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1089         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1090         call \do_sym
1091         jmp error_exit                  /* %ebx: no swapgs flag */
1092         CFI_ENDPROC
1093 END(\sym)
1094 .endm
1095
1096         /* error code is on the stack already */
1097 .macro paranoiderrorentry sym do_sym
1098 ENTRY(\sym)
1099         XCPT_FRAME
1100         PARAVIRT_ADJUST_EXCEPTION_FRAME
1101         subq $ORIG_RAX-R15, %rsp
1102         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1103         call save_paranoid
1104         DEFAULT_FRAME -1
1105         TRACE_IRQS_OFF
1106         movq %rsp,%rdi                  /* pt_regs pointer */
1107         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1108         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1109         call \do_sym
1110         jmp paranoid_exit               /* %ebx: no swapgs flag */
1111         CFI_ENDPROC
1112 END(\sym)
1113 .endm
1114
1115 zeroentry divide_error do_divide_error
1116 zeroentry overflow do_overflow
1117 zeroentry bounds do_bounds
1118 zeroentry invalid_op do_invalid_op
1119 zeroentry device_not_available do_device_not_available
1120 paranoiderrorentry double_fault do_double_fault
1121 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1122 errorentry invalid_TSS do_invalid_TSS
1123 errorentry segment_not_present do_segment_not_present
1124 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1125 zeroentry coprocessor_error do_coprocessor_error
1126 errorentry alignment_check do_alignment_check
1127 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1128
1129
1130         /* Reload gs selector with exception handling */
1131         /* edi:  new selector */
1132 ENTRY(native_load_gs_index)
1133         CFI_STARTPROC
1134         pushfq_cfi
1135         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1136         SWAPGS
1137 gs_change:
1138         movl %edi,%gs
1139 2:      mfence          /* workaround */
1140         SWAPGS
1141         popfq_cfi
1142         ret
1143         CFI_ENDPROC
1144 END(native_load_gs_index)
1145
1146         .section __ex_table,"a"
1147         .align 8
1148         .quad gs_change,bad_gs
1149         .previous
1150         .section .fixup,"ax"
1151         /* running with kernelgs */
1152 bad_gs:
1153         SWAPGS                  /* switch back to user gs */
1154         xorl %eax,%eax
1155         movl %eax,%gs
1156         jmp  2b
1157         .previous
1158
1159 ENTRY(kernel_thread_helper)
1160         pushq $0                # fake return address
1161         CFI_STARTPROC
1162         /*
1163          * Here we are in the child and the registers are set as they were
1164          * at kernel_thread() invocation in the parent.
1165          */
1166         call *%rsi
1167         # exit
1168         mov %eax, %edi
1169         call do_exit
1170         ud2                     # padding for call trace
1171         CFI_ENDPROC
1172 END(kernel_thread_helper)
1173
1174 /*
1175  * execve(). This function needs to use IRET, not SYSRET, to set up all state properly.
1176  *
1177  * C extern interface:
1178  *       extern long execve(const char *name, char **argv, char **envp)
1179  *
1180  * asm input arguments:
1181  *      rdi: name, rsi: argv, rdx: envp
1182  *
1183  * We want to fallback into:
1184  *      extern long sys_execve(const char *name, char **argv,char **envp, struct pt_regs *regs)
1185  *
1186  * do_sys_execve asm fallback arguments:
1187  *      rdi: name, rsi: argv, rdx: envp, rcx: fake frame on the stack
1188  */
1189 ENTRY(kernel_execve)
1190         CFI_STARTPROC
1191         FAKE_STACK_FRAME $0
1192         SAVE_ALL
1193         movq %rsp,%rcx
1194         call sys_execve
1195         movq %rax, RAX(%rsp)
1196         RESTORE_REST
1197         testq %rax,%rax
1198         je int_ret_from_sys_call
1199         RESTORE_ARGS
1200         UNFAKE_STACK_FRAME
1201         ret
1202         CFI_ENDPROC
1203 END(kernel_execve)
1204
1205 /* Call softirq on interrupt stack. Interrupts are off. */
1206 ENTRY(call_softirq)
1207         CFI_STARTPROC
1208         pushq_cfi %rbp
1209         CFI_REL_OFFSET rbp,0
1210         mov  %rsp,%rbp
1211         CFI_DEF_CFA_REGISTER rbp
1212         incl PER_CPU_VAR(irq_count)
1213         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1214         push  %rbp                      # backlink for old unwinder
1215         call __do_softirq
1216         leaveq
1217         CFI_RESTORE             rbp
1218         CFI_DEF_CFA_REGISTER    rsp
1219         CFI_ADJUST_CFA_OFFSET   -8
1220         decl PER_CPU_VAR(irq_count)
1221         ret
1222         CFI_ENDPROC
1223 END(call_softirq)
1224
1225 #ifdef CONFIG_STACK_UNWIND
1226 ENTRY(arch_unwind_init_running)
1227         CFI_STARTPROC
1228         movq    %r15, R15(%rdi)
1229         movq    %r14, R14(%rdi)
1230         xchgq   %rsi, %rdx
1231         movq    %r13, R13(%rdi)
1232         movq    %r12, R12(%rdi)
1233         xorl    %eax, %eax
1234         movq    %rbp, RBP(%rdi)
1235         movq    %rbx, RBX(%rdi)
1236         movq    (%rsp), %r9
1237         xchgq   %rdx, %rcx
1238         movq    %rax, R11(%rdi)
1239         movq    %rax, R10(%rdi)
1240         movq    %rax, R9(%rdi)
1241         movq    %rax, R8(%rdi)
1242         movq    %rax, RAX(%rdi)
1243         movq    %rax, RCX(%rdi)
1244         movq    %rax, RDX(%rdi)
1245         movq    %rax, RSI(%rdi)
1246         movq    %rax, RDI(%rdi)
1247         movq    %rax, ORIG_RAX(%rdi)
1248         movq    %r9, RIP(%rdi)
1249         leaq    8(%rsp), %r9
1250         movq    $__KERNEL_CS, CS(%rdi)
1251         movq    %rax, EFLAGS(%rdi)
1252         movq    %r9, RSP(%rdi)
1253         movq    $__KERNEL_DS, SS(%rdi)
1254         jmpq    *%rcx
1255         CFI_ENDPROC
1256 END(arch_unwind_init_running)
1257 #endif
1258
1259 #ifdef CONFIG_PARAVIRT_XEN
1260 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1261
1262 /*
1263  * A note on the "critical region" in our callback handler.
1264  * We want to avoid stacking callback handlers due to events occurring
1265  * during handling of the last event. To do this, we keep events disabled
1266  * until we've done all processing. HOWEVER, we must enable events before
1267  * popping the stack frame (can't be done atomically) and so it would still
1268  * be possible to get enough handler activations to overflow the stack.
1269  * Although unlikely, bugs of that kind are hard to track down, so we'd
1270  * like to avoid the possibility.
1271  * So, on entry to the handler we detect whether we interrupted an
1272  * existing activation in its critical region -- if so, we pop the current
1273  * activation and restart the handler using the previous one.
1274  */
1275 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1276         CFI_STARTPROC
1277 /*
1278  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1279  * see the correct pointer to the pt_regs
1280  */
1281         movq %rdi, %rsp            # we don't return, adjust the stack frame
1282         CFI_ENDPROC
1283         DEFAULT_FRAME
1284 11:     incl PER_CPU_VAR(irq_count)
1285         movq %rsp,%rbp
1286         CFI_DEF_CFA_REGISTER rbp
1287         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1288         pushq %rbp                      # backlink for old unwinder
1289         call xen_evtchn_do_upcall
1290         popq %rsp
1291         CFI_DEF_CFA_REGISTER rsp
1292         decl PER_CPU_VAR(irq_count)
1293         jmp  error_exit
1294         CFI_ENDPROC
1295 END(xen_do_hypervisor_callback)
1296
1297 /*
1298  * Hypervisor uses this for application faults while it executes.
1299  * We get here for two reasons:
1300  *  1. Fault while reloading DS, ES, FS or GS
1301  *  2. Fault while executing IRET
1302  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1303  * registers that could be reloaded and zeroed the others.
1304  * Category 2 we fix up by killing the current process. We cannot use the
1305  * normal Linux return path in this case because if we use the IRET hypercall
1306  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1307  * We distinguish between categories by comparing each saved segment register
1308  * with its current contents: any discrepancy means we in category 1.
1309  */
1310 ENTRY(xen_failsafe_callback)
1311         INTR_FRAME 1 (6*8)
1312         /*CFI_REL_OFFSET gs,GS*/
1313         /*CFI_REL_OFFSET fs,FS*/
1314         /*CFI_REL_OFFSET es,ES*/
1315         /*CFI_REL_OFFSET ds,DS*/
1316         CFI_REL_OFFSET r11,8
1317         CFI_REL_OFFSET rcx,0
1318         movw %ds,%cx
1319         cmpw %cx,0x10(%rsp)
1320         CFI_REMEMBER_STATE
1321         jne 1f
1322         movw %es,%cx
1323         cmpw %cx,0x18(%rsp)
1324         jne 1f
1325         movw %fs,%cx
1326         cmpw %cx,0x20(%rsp)
1327         jne 1f
1328         movw %gs,%cx
1329         cmpw %cx,0x28(%rsp)
1330         jne 1f
1331         /* All segments match their saved values => Category 2 (Bad IRET). */
1332         movq (%rsp),%rcx
1333         CFI_RESTORE rcx
1334         movq 8(%rsp),%r11
1335         CFI_RESTORE r11
1336         addq $0x30,%rsp
1337         CFI_ADJUST_CFA_OFFSET -0x30
1338         pushq_cfi $0    /* RIP */
1339         pushq_cfi %r11
1340         pushq_cfi %rcx
1341         jmp general_protection
1342         CFI_RESTORE_STATE
1343 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1344         movq (%rsp),%rcx
1345         CFI_RESTORE rcx
1346         movq 8(%rsp),%r11
1347         CFI_RESTORE r11
1348         addq $0x30,%rsp
1349         CFI_ADJUST_CFA_OFFSET -0x30
1350         pushq_cfi $0
1351         SAVE_ALL
1352         jmp error_exit
1353         CFI_ENDPROC
1354 END(xen_failsafe_callback)
1355
1356 apicinterrupt XEN_HVM_EVTCHN_CALLBACK \
1357         xen_hvm_callback_vector xen_evtchn_do_upcall
1358
1359 #endif /* CONFIG_PARAVIRT_XEN */
1360
1361 /*
1362  * Some functions should be protected against kprobes
1363  */
1364         .pushsection .kprobes.text, "ax"
1365
1366 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1367 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1368 paranoiderrorentry stack_segment do_stack_segment
1369 #ifdef CONFIG_PARAVIRT_XEN
1370 zeroentry xen_debug do_debug
1371 zeroentry xen_int3 do_int3
1372 errorentry xen_stack_segment do_stack_segment
1373 #endif
1374 errorentry general_protection do_general_protection
1375 errorentry page_fault do_page_fault
1376 #ifdef CONFIG_KVM_GUEST
1377 errorentry async_page_fault do_async_page_fault
1378 #endif
1379 #ifdef CONFIG_X86_MCE
1380 paranoidzeroentry machine_check *machine_check_vector(%rip)
1381 #endif
1382
1383         /*
1384          * "Paranoid" exit path from exception stack.
1385          * Paranoid because this is used by NMIs and cannot take
1386          * any kernel state for granted.
1387          * We don't do kernel preemption checks here, because only
1388          * NMI should be common and it does not enable IRQs and
1389          * cannot get reschedule ticks.
1390          *
1391          * "trace" is 0 for the NMI handler only, because irq-tracing
1392          * is fundamentally NMI-unsafe. (we cannot change the soft and
1393          * hard flags at once, atomically)
1394          */
1395
1396         /* ebx: no swapgs flag */
1397 ENTRY(paranoid_exit)
1398         DEFAULT_FRAME
1399         DISABLE_INTERRUPTS(CLBR_NONE)
1400         TRACE_IRQS_OFF
1401         testl %ebx,%ebx                         /* swapgs needed? */
1402         jnz paranoid_restore
1403         testl $3,CS(%rsp)
1404         jnz   paranoid_userspace
1405 paranoid_swapgs:
1406         TRACE_IRQS_IRETQ 0
1407         SWAPGS_UNSAFE_STACK
1408         RESTORE_ALL 8
1409         jmp irq_return
1410 paranoid_restore:
1411         TRACE_IRQS_IRETQ 0
1412         RESTORE_ALL 8
1413         jmp irq_return
1414 paranoid_userspace:
1415         GET_THREAD_INFO(%rcx)
1416         movl TI_flags(%rcx),%ebx
1417         andl $_TIF_WORK_MASK,%ebx
1418         jz paranoid_swapgs
1419         movq %rsp,%rdi                  /* &pt_regs */
1420         call sync_regs
1421         movq %rax,%rsp                  /* switch stack for scheduling */
1422         testl $_TIF_NEED_RESCHED,%ebx
1423         jnz paranoid_schedule
1424         movl %ebx,%edx                  /* arg3: thread flags */
1425         TRACE_IRQS_ON
1426         ENABLE_INTERRUPTS(CLBR_NONE)
1427         xorl %esi,%esi                  /* arg2: oldset */
1428         movq %rsp,%rdi                  /* arg1: &pt_regs */
1429         call do_notify_resume
1430         DISABLE_INTERRUPTS(CLBR_NONE)
1431         TRACE_IRQS_OFF
1432         jmp paranoid_userspace
1433 paranoid_schedule:
1434         TRACE_IRQS_ON
1435         ENABLE_INTERRUPTS(CLBR_ANY)
1436         call schedule
1437         DISABLE_INTERRUPTS(CLBR_ANY)
1438         TRACE_IRQS_OFF
1439         jmp paranoid_userspace
1440         CFI_ENDPROC
1441 END(paranoid_exit)
1442
1443 /*
1444  * Exception entry point. This expects an error code/orig_rax on the stack.
1445  * returns in "no swapgs flag" in %ebx.
1446  */
1447 ENTRY(error_entry)
1448         XCPT_FRAME offset=ORIG_RAX-R15+8
1449         /* oldrax contains error code */
1450         cld
1451         movq %rdi, RDI+8(%rsp)
1452         movq %rsi, RSI+8(%rsp)
1453         movq %rdx, RDX+8(%rsp)
1454         movq %rcx, RCX+8(%rsp)
1455         movq %rax, RAX+8(%rsp)
1456         movq  %r8,  R8+8(%rsp)
1457         movq  %r9,  R9+8(%rsp)
1458         movq %r10, R10+8(%rsp)
1459         movq %r11, R11+8(%rsp)
1460         movq_cfi rbx, RBX+8
1461         movq %rbp, RBP+8(%rsp)
1462         movq %r12, R12+8(%rsp)
1463         movq %r13, R13+8(%rsp)
1464         movq %r14, R14+8(%rsp)
1465         movq %r15, R15+8(%rsp)
1466         xorl %ebx,%ebx
1467         testl $3,CS+8(%rsp)
1468         je error_kernelspace
1469 error_swapgs:
1470         SWAPGS
1471 error_sti:
1472         TRACE_IRQS_OFF
1473         ret
1474
1475 /*
1476  * There are two places in the kernel that can potentially fault with
1477  * usergs. Handle them here. The exception handlers after iret run with
1478  * kernel gs again, so don't set the user space flag. B stepping K8s
1479  * sometimes report an truncated RIP for IRET exceptions returning to
1480  * compat mode. Check for these here too.
1481  */
1482 error_kernelspace:
1483         CFI_REL_OFFSET rcx, RCX+8
1484         incl %ebx
1485         leaq irq_return(%rip),%rcx
1486         cmpq %rcx,RIP+8(%rsp)
1487         je error_swapgs
1488         movl %ecx,%eax  /* zero extend */
1489         cmpq %rax,RIP+8(%rsp)
1490         je bstep_iret
1491         cmpq $gs_change,RIP+8(%rsp)
1492         je error_swapgs
1493         jmp error_sti
1494
1495 bstep_iret:
1496         /* Fix truncated RIP */
1497         movq %rcx,RIP+8(%rsp)
1498         jmp error_swapgs
1499         CFI_ENDPROC
1500 END(error_entry)
1501
1502
1503 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1504 ENTRY(error_exit)
1505         DEFAULT_FRAME
1506         movl %ebx,%eax
1507         RESTORE_REST
1508         DISABLE_INTERRUPTS(CLBR_NONE)
1509         TRACE_IRQS_OFF
1510         GET_THREAD_INFO(%rcx)
1511         testl %eax,%eax
1512         jne retint_kernel
1513         LOCKDEP_SYS_EXIT_IRQ
1514         movl TI_flags(%rcx),%edx
1515         movl $_TIF_WORK_MASK,%edi
1516         andl %edi,%edx
1517         jnz retint_careful
1518         jmp retint_swapgs
1519         CFI_ENDPROC
1520 END(error_exit)
1521
1522 /*
1523  * Test if a given stack is an NMI stack or not.
1524  */
1525         .macro test_in_nmi reg stack nmi_ret normal_ret
1526         cmpq %\reg, \stack
1527         ja \normal_ret
1528         subq $EXCEPTION_STKSZ, %\reg
1529         cmpq %\reg, \stack
1530         jb \normal_ret
1531         jmp \nmi_ret
1532         .endm
1533
1534         /* runs on exception stack */
1535 ENTRY(nmi)
1536         INTR_FRAME
1537         PARAVIRT_ADJUST_EXCEPTION_FRAME
1538         /*
1539          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1540          * the iretq it performs will take us out of NMI context.
1541          * This means that we can have nested NMIs where the next
1542          * NMI is using the top of the stack of the previous NMI. We
1543          * can't let it execute because the nested NMI will corrupt the
1544          * stack of the previous NMI. NMI handlers are not re-entrant
1545          * anyway.
1546          *
1547          * To handle this case we do the following:
1548          *  Check the a special location on the stack that contains
1549          *  a variable that is set when NMIs are executing.
1550          *  The interrupted task's stack is also checked to see if it
1551          *  is an NMI stack.
1552          *  If the variable is not set and the stack is not the NMI
1553          *  stack then:
1554          *    o Set the special variable on the stack
1555          *    o Copy the interrupt frame into a "saved" location on the stack
1556          *    o Copy the interrupt frame into a "copy" location on the stack
1557          *    o Continue processing the NMI
1558          *  If the variable is set or the previous stack is the NMI stack:
1559          *    o Modify the "copy" location to jump to the repeate_nmi
1560          *    o return back to the first NMI
1561          *
1562          * Now on exit of the first NMI, we first clear the stack variable
1563          * The NMI stack will tell any nested NMIs at that point that it is
1564          * nested. Then we pop the stack normally with iret, and if there was
1565          * a nested NMI that updated the copy interrupt stack frame, a
1566          * jump will be made to the repeat_nmi code that will handle the second
1567          * NMI.
1568          */
1569
1570         /* Use %rdx as out temp variable throughout */
1571         pushq_cfi %rdx
1572
1573         /*
1574          * If %cs was not the kernel segment, then the NMI triggered in user
1575          * space, which means it is definitely not nested.
1576          */
1577         cmpl $__KERNEL_CS, 16(%rsp)
1578         jne first_nmi
1579
1580         /*
1581          * Check the special variable on the stack to see if NMIs are
1582          * executing.
1583          */
1584         cmpl $1, -8(%rsp)
1585         je nested_nmi
1586
1587         /*
1588          * Now test if the previous stack was an NMI stack.
1589          * We need the double check. We check the NMI stack to satisfy the
1590          * race when the first NMI clears the variable before returning.
1591          * We check the variable because the first NMI could be in a
1592          * breakpoint routine using a breakpoint stack.
1593          */
1594         lea 6*8(%rsp), %rdx
1595         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1596
1597 nested_nmi:
1598         /*
1599          * Do nothing if we interrupted the fixup in repeat_nmi.
1600          * It's about to repeat the NMI handler, so we are fine
1601          * with ignoring this one.
1602          */
1603         movq $repeat_nmi, %rdx
1604         cmpq 8(%rsp), %rdx
1605         ja 1f
1606         movq $end_repeat_nmi, %rdx
1607         cmpq 8(%rsp), %rdx
1608         ja nested_nmi_out
1609
1610 1:
1611         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1612         leaq -6*8(%rsp), %rdx
1613         movq %rdx, %rsp
1614         CFI_ADJUST_CFA_OFFSET 6*8
1615         pushq_cfi $__KERNEL_DS
1616         pushq_cfi %rdx
1617         pushfq_cfi
1618         pushq_cfi $__KERNEL_CS
1619         pushq_cfi $repeat_nmi
1620
1621         /* Put stack back */
1622         addq $(11*8), %rsp
1623         CFI_ADJUST_CFA_OFFSET -11*8
1624
1625 nested_nmi_out:
1626         popq_cfi %rdx
1627
1628         /* No need to check faults here */
1629         INTERRUPT_RETURN
1630
1631 first_nmi:
1632         /*
1633          * Because nested NMIs will use the pushed location that we
1634          * stored in rdx, we must keep that space available.
1635          * Here's what our stack frame will look like:
1636          * +-------------------------+
1637          * | original SS             |
1638          * | original Return RSP     |
1639          * | original RFLAGS         |
1640          * | original CS             |
1641          * | original RIP            |
1642          * +-------------------------+
1643          * | temp storage for rdx    |
1644          * +-------------------------+
1645          * | NMI executing variable  |
1646          * +-------------------------+
1647          * | Saved SS                |
1648          * | Saved Return RSP        |
1649          * | Saved RFLAGS            |
1650          * | Saved CS                |
1651          * | Saved RIP               |
1652          * +-------------------------+
1653          * | copied SS               |
1654          * | copied Return RSP       |
1655          * | copied RFLAGS           |
1656          * | copied CS               |
1657          * | copied RIP              |
1658          * +-------------------------+
1659          * | pt_regs                 |
1660          * +-------------------------+
1661          *
1662          * The saved RIP is used to fix up the copied RIP that a nested
1663          * NMI may zero out. The original stack frame and the temp storage
1664          * is also used by nested NMIs and can not be trusted on exit.
1665          */
1666         /* Set the NMI executing variable on the stack. */
1667         pushq_cfi $1
1668
1669         /* Copy the stack frame to the Saved frame */
1670         .rept 5
1671         pushq_cfi 6*8(%rsp)
1672         .endr
1673
1674         /* Make another copy, this one may be modified by nested NMIs */
1675         .rept 5
1676         pushq_cfi 4*8(%rsp)
1677         .endr
1678
1679         /* Do not pop rdx, nested NMIs will corrupt it */
1680         movq 11*8(%rsp), %rdx
1681
1682         /*
1683          * Everything below this point can be preempted by a nested
1684          * NMI if the first NMI took an exception. Repeated NMIs
1685          * caused by an exception and nested NMI will start here, and
1686          * can still be preempted by another NMI.
1687          */
1688 restart_nmi:
1689         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1690         subq $ORIG_RAX-R15, %rsp
1691         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1692         /*
1693          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1694          * as we should not be calling schedule in NMI context.
1695          * Even with normal interrupts enabled. An NMI should not be
1696          * setting NEED_RESCHED or anything that normal interrupts and
1697          * exceptions might do.
1698          */
1699         call save_paranoid
1700         DEFAULT_FRAME -1
1701         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1702         movq %rsp,%rdi
1703         movq $-1,%rsi
1704         call do_nmi
1705         testl %ebx,%ebx                         /* swapgs needed? */
1706         jnz nmi_restore
1707 nmi_swapgs:
1708         SWAPGS_UNSAFE_STACK
1709 nmi_restore:
1710         RESTORE_ALL 8
1711         /* Clear the NMI executing stack variable */
1712         movq $0, 10*8(%rsp)
1713         jmp irq_return
1714         CFI_ENDPROC
1715 END(nmi)
1716
1717         /*
1718          * If an NMI hit an iret because of an exception or breakpoint,
1719          * it can lose its NMI context, and a nested NMI may come in.
1720          * In that case, the nested NMI will change the preempted NMI's
1721          * stack to jump to here when it does the final iret.
1722          */
1723 repeat_nmi:
1724         INTR_FRAME
1725         /* Update the stack variable to say we are still in NMI */
1726         movq $1, 5*8(%rsp)
1727
1728         /* copy the saved stack back to copy stack */
1729         .rept 5
1730         pushq_cfi 4*8(%rsp)
1731         .endr
1732
1733         jmp restart_nmi
1734         CFI_ENDPROC
1735 end_repeat_nmi:
1736
1737 ENTRY(ignore_sysret)
1738         CFI_STARTPROC
1739         mov $-ENOSYS,%eax
1740         sysret
1741         CFI_ENDPROC
1742 END(ignore_sysret)
1743
1744 /*
1745  * End of kprobes section
1746  */
1747         .popsection