arch/ia64/vmlinux.lds.S

   1 #include <linux/config.h>
   2
   3 #include <asm/cache.h>
   4 #include <asm/ptrace.h>
   5 #include <asm/system.h>
   6 #include <asm/pgtable.h>
   7
   8 #define LOAD_OFFSET KERNEL_START + KERNEL_TR_PAGE_SIZE
   9 #include <asm-generic/vmlinux.lds.h>
  10
  11 OUTPUT_FORMAT("elf64-ia64-little")
  12 OUTPUT_ARCH(ia64)
  13 ENTRY(phys_start)
  14 jiffies = jiffies_64;
  15 SECTIONS
  16 {
  17   /* Sections to be discarded */
  18   /DISCARD/ : {
  19         *(.exit.text)
  20         *(.exit.data)
  21         *(.exitcall.exit)
  22         *(.IA_64.unwind.exit.text)
  23         *(.IA_64.unwind_info.exit.text)
  24         }
  25
  26   v = PAGE_OFFSET;      /* this symbol is here to make debugging easier... */
  27   phys_start = _start - LOAD_OFFSET;
  28
  29   . = KERNEL_START;
  30
  31   _text = .;
  32   _stext = .;
  33
  34   .text : AT(ADDR(.text) - LOAD_OFFSET)
  35     {
  36         *(.text.ivt)
  37         *(.text)
  38     }
  39   .text2 : AT(ADDR(.text2) - LOAD_OFFSET)
  40         { *(.text2) }
  41 #ifdef CONFIG_SMP
  42   .text.lock : AT(ADDR(.text.lock) - LOAD_OFFSET)
  43         { *(.text.lock) }
  44 #endif
  45   _etext = .;
  46
  47   /* Read-only data */
  48
  49   /* Exception table */
  50   . = ALIGN(16);
  51   __ex_table : AT(ADDR(__ex_table) - LOAD_OFFSET)
  52         {
  53           __start___ex_table = .;
  54           *(__ex_table)
  55           __stop___ex_table = .;
  56         }
  57
  58   __mckinley_e9_bundles : AT(ADDR(__mckinley_e9_bundles) - LOAD_OFFSET)
  59         {
  60           __start___mckinley_e9_bundles = .;
  61           *(__mckinley_e9_bundles)
  62           __end___mckinley_e9_bundles = .;
  63         }
  64
  65   /* Global data */
  66   _data = .;
  67
  68 #if defined(CONFIG_IA64_GENERIC)
  69   /* Machine Vector */
  70   . = ALIGN(16);
  71   .machvec : AT(ADDR(.machvec) - LOAD_OFFSET)
  72         {
  73           machvec_start = .;
  74           *(.machvec)
  75           machvec_end = .;
  76         }
  77 #endif
  78
  79   /* Unwind info & table: */
  80   . = ALIGN(8);
  81   .IA_64.unwind_info : AT(ADDR(.IA_64.unwind_info) - LOAD_OFFSET)
  82         { *(.IA_64.unwind_info*) }
  83   .IA_64.unwind : AT(ADDR(.IA_64.unwind) - LOAD_OFFSET)
  84         {
  85           ia64_unw_start = .;
  86           *(.IA_64.unwind*)
  87           ia64_unw_end = .;
  88         }
  89
  90   RODATA
  91
  92   .opd : AT(ADDR(.opd) - LOAD_OFFSET)
  93         { *(.opd) }
  94
  95   /* Initialization code and data: */
  96
  97   . = ALIGN(PAGE_SIZE);
  98   __init_begin = .;
  99   .init.text : AT(ADDR(.init.text) - LOAD_OFFSET)
 100         {
 101           _sinittext = .;
 102           *(.init.text)
 103           _einittext = .;
 104         }
 105
 106   .init.data : AT(ADDR(.init.data) - LOAD_OFFSET)
 107         { *(.init.data) }
 108
 109   .init.ramfs : AT(ADDR(.init.ramfs) - LOAD_OFFSET)
 110         {
 111           __initramfs_start = .;
 112           *(.init.ramfs)
 113           __initramfs_end = .;
 114         }
 115
 116    . = ALIGN(16);
 117   .init.setup : AT(ADDR(.init.setup) - LOAD_OFFSET)
 118         {
 119           __setup_start = .;
 120           *(.init.setup)
 121           __setup_end = .;
 122         }
 123   __param : AT(ADDR(__param) - LOAD_OFFSET)
 124         {
 125           __start___param = .;
 126           *(__param)
 127           __stop___param = .;
 128         }
 129   .initcall.init : AT(ADDR(.initcall.init) - LOAD_OFFSET)
 130         {
 131           __initcall_start = .;
 132           *(.initcall1.init)
 133           *(.initcall2.init)
 134           *(.initcall3.init)
 135           *(.initcall4.init)
 136           *(.initcall5.init)
 137           *(.initcall6.init)
 138           *(.initcall7.init)
 139           __initcall_end = .;
 140         }
 141    __con_initcall_start = .;
 142   .con_initcall.init : AT(ADDR(.con_initcall.init) - LOAD_OFFSET)
 143         { *(.con_initcall.init) }
 144   __con_initcall_end = .;
 145   . = ALIGN(PAGE_SIZE);
 146   __init_end = .;
 147
 148   /* The initial task and kernel stack */
 149   .data.init_task : AT(ADDR(.data.init_task) - LOAD_OFFSET)
 150         { *(.data.init_task) }
 151
 152   .data.page_aligned : AT(ADDR(.data.page_aligned) - LOAD_OFFSET)
 153         { *(__special_page_section)
 154           __start_gate_section = .;
 155           *(.text.gate)
 156           __stop_gate_section = .;
 157         }
 158
 159   . = ALIGN(SMP_CACHE_BYTES);
 160   .data.cacheline_aligned : AT(ADDR(.data.cacheline_aligned) - LOAD_OFFSET)
 161         { *(.data.cacheline_aligned) }
 162
 163   /* Per-cpu data: */
 164   . = ALIGN(PERCPU_PAGE_SIZE);
 165   __phys_per_cpu_start = .;
 166   .data.percpu PERCPU_ADDR : AT(__phys_per_cpu_start - LOAD_OFFSET)
 167         {
 168                 __per_cpu_start = .;
 169                 *(.data.percpu)
 170                 __per_cpu_end = .;
 171         }
 172   . = __phys_per_cpu_start + PERCPU_PAGE_SIZE;  /* ensure percpu data fits into percpu page size */
 173
 174   .data : AT(ADDR(.data) - LOAD_OFFSET)
 175         { *(.data) *(.gnu.linkonce.d*) CONSTRUCTORS }
 176
 177   . = ALIGN(16);
 178   __gp = . + 0x200000;  /* gp must be 16-byte aligned for exc. table */
 179
 180   .got : AT(ADDR(.got) - LOAD_OFFSET)
 181         { *(.got.plt) *(.got) }
 182   /* We want the small data sections together, so single-instruction offsets
 183      can access them all, and initialized data all before uninitialized, so
 184      we can shorten the on-disk segment size.  */
 185   .sdata : AT(ADDR(.sdata) - LOAD_OFFSET)
 186         { *(.sdata) }
 187   _edata  =  .;
 188   _bss = .;
 189   .sbss : AT(ADDR(.sbss) - LOAD_OFFSET)
 190         { *(.sbss) *(.scommon) }
 191   .bss : AT(ADDR(.bss) - LOAD_OFFSET)
 192         { *(.bss) *(COMMON) }
 193
 194   _end = .;
 195
 196   /* Stabs debugging sections.  */
 197   .stab 0 : { *(.stab) }
 198   .stabstr 0 : { *(.stabstr) }
 199   .stab.excl 0 : { *(.stab.excl) }
 200   .stab.exclstr 0 : { *(.stab.exclstr) }
 201   .stab.index 0 : { *(.stab.index) }
 202   .stab.indexstr 0 : { *(.stab.indexstr) }
 203   /* DWARF debug sections.
 204      Symbols in the DWARF debugging sections are relative to the beginning
 205      of the section so we begin them at 0.  */
 206   /* DWARF 1 */
 207   .debug          0 : { *(.debug) }
 208   .line           0 : { *(.line) }
 209   /* GNU DWARF 1 extensions */
 210   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 211   .debug_sfnames  0 : { *(.debug_sfnames) }
 212   /* DWARF 1.1 and DWARF 2 */
 213   .debug_aranges  0 : { *(.debug_aranges) }
 214   .debug_pubnames 0 : { *(.debug_pubnames) }
 215   /* DWARF 2 */
 216   .debug_info     0 : { *(.debug_info) }
 217   .debug_abbrev   0 : { *(.debug_abbrev) }
 218   .debug_line     0 : { *(.debug_line) }
 219   .debug_frame    0 : { *(.debug_frame) }
 220   .debug_str      0 : { *(.debug_str) }
 221   .debug_loc      0 : { *(.debug_loc) }
 222   .debug_macinfo  0 : { *(.debug_macinfo) }
 223   /* SGI/MIPS DWARF 2 extensions */
 224   .debug_weaknames 0 : { *(.debug_weaknames) }
 225   .debug_funcnames 0 : { *(.debug_funcnames) }
 226   .debug_typenames 0 : { *(.debug_typenames) }
 227   .debug_varnames  0 : { *(.debug_varnames) }
 228   /* These must appear regardless of  .  */
 229   /* Discard them for now since Intel SoftSDV cannot handle them.
 230   .comment 0 : { *(.comment) }
 231   .note 0 : { *(.note) }
 232   */
 233   /DISCARD/ : { *(.comment) }
 234   /DISCARD/ : { *(.note) }
 235 }