arch/mips/vmlinux.lds.S

   1 #include <asm-generic/vmlinux.lds.h>
   2
   3 OUTPUT_ARCH(mips)
   4 ENTRY(kernel_entry)
   5 jiffies = JIFFIES32;
   6 SECTIONS
   7 {
   8   . = LOADADDR;
   9   /* read-only */
  10   _text = .;                    /* Text and read-only data */
  11   .text : {
  12     *(.text)
  13     *(.fixup)
  14     *(.gnu.warning)
  15   } =0
  16
  17   _etext = .;                   /* End of text section */
  18
  19   . = ALIGN(16);                /* Exception table */
  20   __start___ex_table = .;
  21   __ex_table : { *(__ex_table) }
  22   __stop___ex_table = .;
  23
  24   __start___dbe_table = .;      /* Exception table for data bus errors */
  25   __dbe_table : { *(__dbe_table) }
  26   __stop___dbe_table = .;
  27
  28   RODATA
  29
  30   . = ALIGN(64);
  31
  32   /* writeable */
  33   .data : {                     /* Data */
  34     *(.data)
  35
  36    /* Align the initial ramdisk image (INITRD) on page boundaries. */
  37    . = ALIGN(4096);
  38    __rd_start = .;
  39    *(.initrd)
  40    . = ALIGN(4096);
  41    __rd_end = .;
  42
  43     CONSTRUCTORS
  44   }
  45   _gp = . + 0x8000;
  46   .lit8 : { *(.lit8) }
  47   .lit4 : { *(.lit4) }
  48   /* We want the small data sections together, so single-instruction offsets
  49      can access them all, and initialized data all before uninitialized, so
  50      we can shorten the on-disk segment size.  */
  51   .sdata     : { *(.sdata) }
  52
  53   . = ALIGN(4096);
  54   __nosave_begin = .;
  55   .data_nosave : { *(.data.nosave) }
  56   . = ALIGN(4096);
  57   __nosave_end = .;
  58
  59   . = ALIGN(4096);
  60   .data.page_aligned : { *(.data.idt) }
  61
  62   . = ALIGN(32);
  63   .data.cacheline_aligned : { *(.data.cacheline_aligned) }
  64
  65   _edata =  .;                  /* End of data section */
  66
  67   . = ALIGN(8192);              /* init_task */
  68   .data.init_task : { *(.data.init_task) }
  69
  70   /* will be freed after init */
  71   . = ALIGN(4096);              /* Init code and data */
  72   __init_begin = .;
  73   /* /DISCARD/ doesn't work for .reginfo */
  74   .reginfo : { *(.reginfo) }
  75   .init.text : {
  76         _sinittext = .;
  77         *(.init.text)
  78         _einittext = .;
  79   }
  80   .init.data : { *(.init.data) }
  81   . = ALIGN(16);
  82   __setup_start = .;
  83   .init.setup : { *(.init.setup) }
  84   __setup_end = .;
  85   __start___param = .;
  86   __param : { *(__param) }
  87   __stop___param = .;
  88   __initcall_start = .;
  89   .initcall.init : {
  90         *(.initcall1.init)
  91         *(.initcall2.init)
  92         *(.initcall3.init)
  93         *(.initcall4.init)
  94         *(.initcall5.init)
  95         *(.initcall6.init)
  96         *(.initcall7.init)
  97   }
  98   __initcall_end = .;
  99   __con_initcall_start = .;
 100   .con_initcall.init : { *(.con_initcall.init) }
 101   __con_initcall_end = .;
 102   SECURITY_INIT
 103   . = ALIGN(4096);
 104   __initramfs_start = .;
 105   .init.ramfs : { *(.init.ramfs) }
 106   __initramfs_end = .;
 107   . = ALIGN(32);
 108   __per_cpu_start = .;
 109   .data.percpu  : { *(.data.percpu) }
 110   __per_cpu_end = .;
 111   . = ALIGN(4096);
 112   __init_end = .;
 113   /* freed after init ends here */
 114
 115   __bss_start = .;              /* BSS */
 116   .sbss      : {
 117     *(.sbss)
 118     *(.scommon)
 119   }
 120   .bss : {
 121     *(.bss)
 122     *(COMMON)
 123   }
 124   __bss_stop = .;
 125
 126   _end = . ;
 127
 128   /* Sections to be discarded */
 129   /DISCARD/ : {
 130         *(.exit.text)
 131         *(.exit.data)
 132         *(.exitcall.exit)
 133   }
 134
 135   /* This is the MIPS specific mdebug section.  */
 136   .mdebug : { *(.mdebug) }
 137   /* These are needed for ELF backends which have not yet been
 138      converted to the new style linker.  */
 139   .stab 0 : { *(.stab) }
 140   .stabstr 0 : { *(.stabstr) }
 141   /* DWARF debug sections.
 142      Symbols in the .debug DWARF section are relative to the beginning of the
 143      section so we begin .debug at 0.  It's not clear yet what needs to happen
 144      for the others.   */
 145   .debug          0 : { *(.debug) }
 146   .debug_srcinfo  0 : { *(.debug_srcinfo) }
 147   .debug_aranges  0 : { *(.debug_aranges) }
 148   .debug_pubnames 0 : { *(.debug_pubnames) }
 149   .debug_sfnames  0 : { *(.debug_sfnames) }
 150   .line           0 : { *(.line) }
 151   /* These must appear regardless of  .  */
 152   .gptab.sdata : { *(.gptab.data) *(.gptab.sdata) }
 153   .gptab.sbss : { *(.gptab.bss) *(.gptab.sbss) }
 154   .comment : { *(.comment) }
 155   .note : { *(.note) }
 156 }