arch/ia64/kernel/gate.S

   1 /*
   2  * This file contains the code that gets mapped at the upper end of each task's text
   3  * region.  For now, it contains the signal trampoline code only.
   4  *
   5  * Copyright (C) 1999-2003 Hewlett-Packard Co
   6  *      David Mosberger-Tang <davidm@hpl.hp.com>
   7  */
   8
   9 #include <linux/config.h>
  10
  11 #include <asm/asmmacro.h>
  12 #include <asm/errno.h>
  13 #include <asm/offsets.h>
  14 #include <asm/sigcontext.h>
  15 #include <asm/system.h>
  16 #include <asm/unistd.h>
  17
  18 /*
  19  * We can't easily refer to symbols inside the kernel.  To avoid full runtime relocation,
  20  * complications with the linker (which likes to create PLT stubs for branches
  21  * to targets outside the shared object) and to avoid multi-phase kernel builds, we
  22  * simply create minimalistic "patch lists" in special ELF sections.
  23  */
  24         .section ".data.patch.fsyscall_table", "a"
  25         .previous
  26 #define LOAD_FSYSCALL_TABLE(reg)                        \
  27 [1:]    movl reg=0;                                     \
  28         .xdata4 ".data.patch.fsyscall_table", 1b-.
  29
  30         .section ".data.patch.brl_fsys_bubble_down", "a"
  31         .previous
  32 #define BRL_COND_FSYS_BUBBLE_DOWN(pr)                   \
  33 [1:](pr)brl.cond.sptk 0;                                \
  34         .xdata4 ".data.patch.brl_fsys_bubble_down", 1b-.
  35
  36 GLOBAL_ENTRY(__kernel_syscall_via_break)
  37         .prologue
  38         .altrp b6
  39         .body
  40         /*
  41          * Note: for (fast) syscall restart to work, the break instruction must be
  42          *       the first one in the bundle addressed by syscall_via_break.
  43          */
  44 { .mib
  45         break 0x100000
  46         nop.i 0
  47         br.ret.sptk.many b6
  48 }
  49 END(__kernel_syscall_via_break)
  50
  51 /*
  52  * On entry:
  53  *      r11 = saved ar.pfs
  54  *      r15 = system call #
  55  *      b0  = saved return address
  56  *      b6  = return address
  57  * On exit:
  58  *      r11 = saved ar.pfs
  59  *      r15 = system call #
  60  *      b0  = saved return address
  61  *      all other "scratch" registers:  undefined
  62  *      all "preserved" registers:      same as on entry
  63  */
  64
  65 GLOBAL_ENTRY(__kernel_syscall_via_epc)
  66         .prologue
  67         .altrp b6
  68         .body
  69 {
  70         /*
  71          * Note: the kernel cannot assume that the first two instructions in this
  72          * bundle get executed.  The remaining code must be safe even if
  73          * they do not get executed.
  74          */
  75         adds r17=-1024,r15
  76         mov r10=0                               // default to successful syscall execution
  77         epc
  78 }
  79         ;;
  80         rsm psr.be // note: on McKinley "rsm psr.be/srlz.d" is slightly faster than "rum psr.be"
  81         LOAD_FSYSCALL_TABLE(r14)
  82
  83         mov r16=IA64_KR(CURRENT)                // 12 cycle read latency
  84         mov r19=NR_syscalls-1
  85         ;;
  86         shladd r18=r17,3,r14
  87
  88         srlz.d
  89         cmp.ne p8,p0=r0,r0                      // p8 <- FALSE
  90         /* Note: if r17 is a NaT, p6 will be set to zero.  */
  91         cmp.geu p6,p7=r19,r17                   // (syscall > 0 && syscall < 1024+NR_syscalls)?
  92         ;;
  93 (p6)    ld8 r18=[r18]
  94         mov r29=psr                             // read psr (12 cyc load latency)
  95         add r14=-8,r14                          // r14 <- addr of fsys_bubble_down entry
  96         ;;
  97 (p6)    mov b7=r18
  98 (p6)    tbit.z p8,p0=r18,0
  99 (p8)    br.dptk.many b7
 100
 101         mov r27=ar.rsc
 102         mov r21=ar.fpsr
 103         mov r26=ar.pfs
 104 /*
 105  * brl.cond doesn't work as intended because the linker would convert this branch
 106  * into a branch to a PLT.  Perhaps there will be a way to avoid this with some
 107  * future version of the linker.  In the meantime, we just use an indirect branch
 108  * instead.
 109  */
 110 #ifdef CONFIG_ITANIUM
 111 (p6)    ld8 r14=[r14]                           // r14 <- fsys_bubble_down
 112         ;;
 113 (p6)    mov b7=r14
 114 (p6)    br.sptk.many b7
 115 #else
 116         BRL_COND_FSYS_BUBBLE_DOWN(p6)
 117 #endif
 118
 119         mov r10=-1
 120         mov r8=ENOSYS
 121         MCKINLEY_E9_WORKAROUND
 122         br.ret.sptk.many b6
 123 END(__kernel_syscall_via_epc)
 124
 125 #       define ARG0_OFF         (16 + IA64_SIGFRAME_ARG0_OFFSET)
 126 #       define ARG1_OFF         (16 + IA64_SIGFRAME_ARG1_OFFSET)
 127 #       define ARG2_OFF         (16 + IA64_SIGFRAME_ARG2_OFFSET)
 128 #       define SIGHANDLER_OFF   (16 + IA64_SIGFRAME_HANDLER_OFFSET)
 129 #       define SIGCONTEXT_OFF   (16 + IA64_SIGFRAME_SIGCONTEXT_OFFSET)
 130
 131 #       define FLAGS_OFF        IA64_SIGCONTEXT_FLAGS_OFFSET
 132 #       define CFM_OFF          IA64_SIGCONTEXT_CFM_OFFSET
 133 #       define FR6_OFF          IA64_SIGCONTEXT_FR6_OFFSET
 134 #       define BSP_OFF          IA64_SIGCONTEXT_AR_BSP_OFFSET
 135 #       define RNAT_OFF         IA64_SIGCONTEXT_AR_RNAT_OFFSET
 136 #       define UNAT_OFF         IA64_SIGCONTEXT_AR_UNAT_OFFSET
 137 #       define FPSR_OFF         IA64_SIGCONTEXT_AR_FPSR_OFFSET
 138 #       define PR_OFF           IA64_SIGCONTEXT_PR_OFFSET
 139 #       define RP_OFF           IA64_SIGCONTEXT_IP_OFFSET
 140 #       define SP_OFF           IA64_SIGCONTEXT_R12_OFFSET
 141 #       define RBS_BASE_OFF     IA64_SIGCONTEXT_RBS_BASE_OFFSET
 142 #       define LOADRS_OFF       IA64_SIGCONTEXT_LOADRS_OFFSET
 143 #       define base0            r2
 144 #       define base1            r3
 145         /*
 146          * When we get here, the memory stack looks like this:
 147          *
 148          *   +===============================+
 149          *   |                               |
 150          *   //     struct sigframe          //
 151          *   |                               |
 152          *   +-------------------------------+ <-- sp+16
 153          *   |      16 byte of scratch       |
 154          *   |            space              |
 155          *   +-------------------------------+ <-- sp
 156          *
 157          * The register stack looks _exactly_ the way it looked at the time the signal
 158          * occurred.  In other words, we're treading on a potential mine-field: each
 159          * incoming general register may be a NaT value (including sp, in which case the
 160          * process ends up dying with a SIGSEGV).
 161          *
 162          * The first thing need to do is a cover to get the registers onto the backing
 163          * store.  Once that is done, we invoke the signal handler which may modify some
 164          * of the machine state.  After returning from the signal handler, we return
 165          * control to the previous context by executing a sigreturn system call.  A signal
 166          * handler may call the rt_sigreturn() function to directly return to a given
 167          * sigcontext.  However, the user-level sigreturn() needs to do much more than
 168          * calling the rt_sigreturn() system call as it needs to unwind the stack to
 169          * restore preserved registers that may have been saved on the signal handler's
 170          * call stack.
 171          */
 172
 173 #define SIGTRAMP_SAVES                                                                          \
 174         .unwabi 3, 's';         /* mark this as a sigtramp handler (saves scratch regs) */      \
 175         .unwabi @svr4, 's'; /* backwards compatibility with old unwinders (remove in v2.7) */   \
 176         .savesp ar.unat, UNAT_OFF+SIGCONTEXT_OFF;                                               \
 177         .savesp ar.fpsr, FPSR_OFF+SIGCONTEXT_OFF;                                               \
 178         .savesp pr, PR_OFF+SIGCONTEXT_OFF;                                                      \
 179         .savesp rp, RP_OFF+SIGCONTEXT_OFF;                                                      \
 180         .savesp ar.pfs, CFM_OFF+SIGCONTEXT_OFF;                                                 \
 181         .vframesp SP_OFF+SIGCONTEXT_OFF
 182
 183 GLOBAL_ENTRY(__kernel_sigtramp)
 184         // describe the state that is active when we get here:
 185         .prologue
 186         SIGTRAMP_SAVES
 187         .body
 188
 189         .label_state 1
 190
 191         adds base0=SIGHANDLER_OFF,sp
 192         adds base1=RBS_BASE_OFF+SIGCONTEXT_OFF,sp
 193         br.call.sptk.many rp=1f
 194 1:
 195         ld8 r17=[base0],(ARG0_OFF-SIGHANDLER_OFF)       // get pointer to signal handler's plabel
 196         ld8 r15=[base1]                                 // get address of new RBS base (or NULL)
 197         cover                           // push args in interrupted frame onto backing store
 198         ;;
 199         cmp.ne p8,p0=r15,r0             // do we need to switch the rbs?
 200         mov.m r9=ar.bsp                 // fetch ar.bsp
 201         .spillsp.p p8, ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
 202 (p8)    br.cond.spnt setup_rbs          // yup -> (clobbers r14, r15, and r16)
 203 back_from_setup_rbs:
 204         alloc r8=ar.pfs,0,0,3,0
 205         ld8 out0=[base0],16             // load arg0 (signum)
 206         adds base1=(ARG1_OFF-(RBS_BASE_OFF+SIGCONTEXT_OFF)),base1
 207         ;;
 208         ld8 out1=[base1]                // load arg1 (siginfop)
 209         ld8 r10=[r17],8                 // get signal handler entry point
 210         ;;
 211         ld8 out2=[base0]                // load arg2 (sigcontextp)
 212         ld8 gp=[r17]                    // get signal handler's global pointer
 213         adds base0=(BSP_OFF+SIGCONTEXT_OFF),sp
 214         ;;
 215         .spillsp ar.bsp, BSP_OFF+SIGCONTEXT_OFF
 216         st8 [base0]=r9                  // save sc_ar_bsp
 217         adds base0=(FR6_OFF+SIGCONTEXT_OFF),sp
 218         adds base1=(FR6_OFF+16+SIGCONTEXT_OFF),sp
 219         ;;
 220         stf.spill [base0]=f6,32
 221         stf.spill [base1]=f7,32
 222         ;;
 223         stf.spill [base0]=f8,32
 224         stf.spill [base1]=f9,32
 225         mov b6=r10
 226         ;;
 227         stf.spill [base0]=f10,32
 228         stf.spill [base1]=f11,32
 229         ;;
 230         stf.spill [base0]=f12,32
 231         stf.spill [base1]=f13,32
 232         ;;
 233         stf.spill [base0]=f14,32
 234         stf.spill [base1]=f15,32
 235         br.call.sptk.many rp=b6                 // call the signal handler
 236 .ret0:  adds base0=(BSP_OFF+SIGCONTEXT_OFF),sp
 237         ;;
 238         ld8 r15=[base0],(CFM_OFF-BSP_OFF)       // fetch sc_ar_bsp and advance to CFM_OFF
 239         mov r14=ar.bsp
 240         ;;
 241         cmp.ne p8,p0=r14,r15                    // do we need to restore the rbs?
 242 (p8)    br.cond.spnt restore_rbs                // yup -> (clobbers r14-r18, f6 & f7)
 243         ;;
 244 back_from_restore_rbs:
 245         adds base0=(FR6_OFF+SIGCONTEXT_OFF),sp
 246         adds base1=(FR6_OFF+16+SIGCONTEXT_OFF),sp
 247         ;;
 248         ldf.fill f6=[base0],32
 249         ldf.fill f7=[base1],32
 250         ;;
 251         ldf.fill f8=[base0],32
 252         ldf.fill f9=[base1],32
 253         ;;
 254         ldf.fill f10=[base0],32
 255         ldf.fill f11=[base1],32
 256         ;;
 257         ldf.fill f12=[base0],32
 258         ldf.fill f13=[base1],32
 259         ;;
 260         ldf.fill f14=[base0],32
 261         ldf.fill f15=[base1],32
 262         mov r15=__NR_rt_sigreturn
 263         .restore sp                             // pop .prologue
 264         break __BREAK_SYSCALL
 265
 266         .prologue
 267         SIGTRAMP_SAVES
 268 setup_rbs:
 269         mov ar.rsc=0                            // put RSE into enforced lazy mode
 270         ;;
 271         .save ar.rnat, r16
 272         mov r16=ar.rnat                         // save RNaT before switching backing store area
 273         adds r14=(RNAT_OFF+SIGCONTEXT_OFF),sp
 274
 275         mov ar.bspstore=r15                     // switch over to new register backing store area
 276         ;;
 277         .spillsp ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
 278         st8 [r14]=r16                           // save sc_ar_rnat
 279         .body
 280         adds r14=(LOADRS_OFF+SIGCONTEXT_OFF),sp
 281
 282         mov.m r16=ar.bsp                        // sc_loadrs <- (new bsp - new bspstore) << 16
 283         ;;
 284         invala
 285         sub r15=r16,r15
 286         ;;
 287         shl r15=r15,16
 288         ;;
 289         st8 [r14]=r15                           // save sc_loadrs
 290         mov ar.rsc=0xf                          // set RSE into eager mode, pl 3
 291         .restore sp                             // pop .prologue
 292         br.cond.sptk back_from_setup_rbs
 293
 294         .prologue
 295         SIGTRAMP_SAVES
 296         .spillsp ar.rnat, RNAT_OFF+SIGCONTEXT_OFF
 297         .body
 298 restore_rbs:
 299         // On input:
 300         //      r14 = bsp1 (bsp at the time of return from signal handler)
 301         //      r15 = bsp0 (bsp at the time the signal occurred)
 302         //
 303         // Here, we need to calculate bspstore0, the value that ar.bspstore needs
 304         // to be set to, based on bsp0 and the size of the dirty partition on
 305         // the alternate stack (sc_loadrs >> 16).  This can be done with the
 306         // following algorithm:
 307         //
 308         //  bspstore0 = rse_skip_regs(bsp0, -rse_num_regs(bsp1 - (loadrs >> 19), bsp1));
 309         //
 310         // This is what the code below does.
 311         //
 312         alloc r2=ar.pfs,0,0,0,0                 // alloc null frame
 313         adds r16=(LOADRS_OFF+SIGCONTEXT_OFF),sp
 314         adds r18=(RNAT_OFF+SIGCONTEXT_OFF),sp
 315         ;;
 316         ld8 r17=[r16]
 317         ld8 r16=[r18]                   // get new rnat
 318         extr.u r18=r15,3,6      // r18 <- rse_slot_num(bsp0)
 319         ;;
 320         mov ar.rsc=r17                  // put RSE into enforced lazy mode
 321         shr.u r17=r17,16
 322         ;;
 323         sub r14=r14,r17         // r14 (bspstore1) <- bsp1 - (sc_loadrs >> 16)
 324         shr.u r17=r17,3         // r17 <- (sc_loadrs >> 19)
 325         ;;
 326         loadrs                  // restore dirty partition
 327         extr.u r14=r14,3,6      // r14 <- rse_slot_num(bspstore1)
 328         ;;
 329         add r14=r14,r17         // r14 <- rse_slot_num(bspstore1) + (sc_loadrs >> 19)
 330         ;;
 331         shr.u r14=r14,6         // r14 <- (rse_slot_num(bspstore1) + (sc_loadrs >> 19))/0x40
 332         ;;
 333         sub r14=r14,r17         // r14 <- -rse_num_regs(bspstore1, bsp1)
 334         movl r17=0x8208208208208209
 335         ;;
 336         add r18=r18,r14         // r18 (delta) <- rse_slot_num(bsp0) - rse_num_regs(bspstore1,bsp1)
 337         setf.sig f7=r17
 338         cmp.lt p7,p0=r14,r0     // p7 <- (r14 < 0)?
 339         ;;
 340 (p7)    adds r18=-62,r18        // delta -= 62
 341         ;;
 342         setf.sig f6=r18
 343         ;;
 344         xmpy.h f6=f6,f7
 345         ;;
 346         getf.sig r17=f6
 347         ;;
 348         add r17=r17,r18
 349         shr r18=r18,63
 350         ;;
 351         shr r17=r17,5
 352         ;;
 353         sub r17=r17,r18         // r17 = delta/63
 354         ;;
 355         add r17=r14,r17         // r17 <- delta/63 - rse_num_regs(bspstore1, bsp1)
 356         ;;
 357         shladd r15=r17,3,r15    // r15 <- bsp0 + 8*(delta/63 - rse_num_regs(bspstore1, bsp1))
 358         ;;
 359         mov ar.bspstore=r15                     // switch back to old register backing store area
 360         ;;
 361         mov ar.rnat=r16                         // restore RNaT
 362         mov ar.rsc=0xf                          // (will be restored later on from sc_ar_rsc)
 363         // invala not necessary as that will happen when returning to user-mode
 364         br.cond.sptk back_from_restore_rbs
 365 END(__kernel_sigtramp)