arch/ppc64/kernel/vdso32/vdso32.lds.S

   1
   2 /*
   3  * This is the infamous ld script for the 32 bits vdso
   4  * library
   5  */
   6 #include <asm/vdso.h>
   7
   8 /* Default link addresses for the vDSOs */
   9 OUTPUT_FORMAT("elf32-powerpc", "elf32-powerpc", "elf32-powerpc")
  10 OUTPUT_ARCH(powerpc:common)
  11 ENTRY(_start)
  12
  13 SECTIONS
  14 {
  15   . = VDSO32_LBASE + SIZEOF_HEADERS;
  16   .hash           : { *(.hash) }                        :text
  17   .dynsym         : { *(.dynsym) }
  18   .dynstr         : { *(.dynstr) }
  19   .gnu.version    : { *(.gnu.version) }
  20   .gnu.version_d  : { *(.gnu.version_d) }
  21   .gnu.version_r  : { *(.gnu.version_r) }
  22
  23   . = ALIGN (16);
  24   .text :
  25   {
  26     *(.text .stub .text.* .gnu.linkonce.t.*)
  27   }
  28   PROVIDE (__etext = .);
  29   PROVIDE (_etext = .);
  30   PROVIDE (etext = .);
  31
  32   /* Other stuff is appended to the text segment: */
  33   .rodata               : { *(.rodata .rodata.* .gnu.linkonce.r.*) }
  34   .rodata1              : { *(.rodata1) }
  35
  36   .eh_frame_hdr         : { *(.eh_frame_hdr) }          :text   :eh_frame_hdr
  37   .eh_frame             : { KEEP (*(.eh_frame)) }       :text
  38   .gcc_except_table     : { *(.gcc_except_table) }
  39   .fixup                : { *(.fixup) }
  40
  41   .got ALIGN(4)         : { *(.got.plt) *(.got) }
  42
  43   .dynamic              : { *(.dynamic) }               :text   :dynamic
  44
  45   _end = .;
  46   __end = .;
  47   PROVIDE (end = .);
  48
  49
  50   /* Stabs debugging sections are here too
  51    */
  52   .stab 0 : { *(.stab) }
  53   .stabstr 0 : { *(.stabstr) }
  54   .stab.excl 0 : { *(.stab.excl) }
  55   .stab.exclstr 0 : { *(.stab.exclstr) }
  56   .stab.index 0 : { *(.stab.index) }
  57   .stab.indexstr 0 : { *(.stab.indexstr) }
  58   .comment 0 : { *(.comment) }
  59   .debug 0 : { *(.debug) }
  60   .line 0 : { *(.line) }
  61
  62   .debug_srcinfo 0 : { *(.debug_srcinfo) }
  63   .debug_sfnames 0 : { *(.debug_sfnames) }
  64
  65   .debug_aranges 0 : { *(.debug_aranges) }
  66   .debug_pubnames 0 : { *(.debug_pubnames) }
  67
  68   .debug_info 0 : { *(.debug_info .gnu.linkonce.wi.*) }
  69   .debug_abbrev 0 : { *(.debug_abbrev) }
  70   .debug_line 0 : { *(.debug_line) }
  71   .debug_frame 0 : { *(.debug_frame) }
  72   .debug_str 0 : { *(.debug_str) }
  73   .debug_loc 0 : { *(.debug_loc) }
  74   .debug_macinfo 0 : { *(.debug_macinfo) }
  75
  76   .debug_weaknames 0 : { *(.debug_weaknames) }
  77   .debug_funcnames 0 : { *(.debug_funcnames) }
  78   .debug_typenames 0 : { *(.debug_typenames) }
  79   .debug_varnames 0 : { *(.debug_varnames) }
  80
  81   /DISCARD/ : { *(.note.GNU-stack) }
  82   /DISCARD/ : { *(.data .data.* .gnu.linkonce.d.* .sdata*) }
  83   /DISCARD/ : { *(.bss .sbss .dynbss .dynsbss) }
  84 }
  85
  86
  87 PHDRS
  88 {
  89   text PT_LOAD FILEHDR PHDRS FLAGS(5); /* PF_R|PF_X */
  90   dynamic PT_DYNAMIC FLAGS(4); /* PF_R */
  91   eh_frame_hdr 0x6474e550; /* PT_GNU_EH_FRAME, but ld doesn't match the name */
  92 }
  93
  94
  95 /*
  96  * This controls what symbols we export from the DSO.
  97  */
  98 VERSION
  99 {
 100   VDSO_VERSION_STRING {
 101     global:
 102         __kernel_datapage_offset; /* Has to be there for the kernel to find it */
 103         __kernel_get_syscall_map;
 104         __kernel_gettimeofday;
 105         __kernel_sync_dicache;
 106         __kernel_sync_dicache_p5;
 107         __kernel_sigtramp32;
 108         __kernel_sigtramp_rt32;
 109     local: *;
 110   };
 111 }