configure.ac

   1 dnl Configure script for NBD system
   2 dnl (c) 1998 Martin Mares <mj@ucw.cz>, (c) 2000 Pavel Machek <pavel@ucw.cz>,
   3 dnl (c) 2003-2006 Wouter Verhelst <wouter@debian.org>
   4 AC_INIT([nbd],[2.9.20],[wouter@debian.org])
   5 AM_INIT_AUTOMAKE(foreign dist-bzip2)
   6 AM_MAINTAINER_MODE
   7
   8 AC_ARG_ENABLE(
   9   lfs,
  10   AC_HELP_STRING(--disable-lfs,Disable Large File Support (default on)),
  11   [
  12     if test "x$enableval" = "xyes" ; then
  13       NBD_LFS=1
  14     else
  15       NBD_LFS=0
  16     fi
  17   ],
  18   [NBD_LFS=1]
  19 )
  20 AC_MSG_CHECKING([whether Large File Support should be enabled])
  21 if test $NBD_LFS -eq 1; then
  22   AC_DEFINE(NBD_LFS,1, [Define to 1 if Large File Support should be enabled])
  23   AC_MSG_RESULT([yes])
  24 else
  25   AC_DEFINE(NBD_LFS,0)
  26   AC_MSG_RESULT([no])
  27 fi
  28
  29 AC_ARG_ENABLE(
  30   syslog,
  31   AC_HELP_STRING(--enable-syslog,Enable Syslog logging),
  32   [
  33     if test "x$enableval" = "xyes" ; then
  34       ISSERVER=1
  35     else
  36       ISSERVER=0
  37     fi
  38   ],
  39   [ISSERVER=0]
  40 )
  41
  42 AC_MSG_CHECKING([whether syslog logging is requested])
  43 if test $ISSERVER -eq 1; then
  44   AC_DEFINE(ISSERVER,1, [Define to 1 if you want nbd-server to log through syslog])
  45   AC_MSG_RESULT([yes])
  46 else
  47   AC_MSG_RESULT([no])
  48 fi
  49
  50 AC_ARG_ENABLE(
  51   debug,
  52   AC_HELP_STRING(--enable-debug,Build a debugging version of the server),
  53   [
  54     if test "x$enableval" = "xyes"; then
  55       DODBG=1
  56     else
  57       DODBG=0
  58     fi
  59   ],
  60   [DODBG=0]
  61 )
  62
  63 AC_MSG_CHECKING([whether a debugging version is requested])
  64 if test $DODBG -eq 1; then
  65   AC_MSG_RESULT([yes])
  66   if test $ISSERVER -eq 1; then
  67     AC_MSG_ERROR([You requested both syslog logging and a debugging version of the server. Bad idea!])
  68   fi
  69   AC_DEFINE(DODBG,1,[Define if you want a debugging version of nbd-server (lots of copious output)])
  70   AC_DEFINE(NOFORK,1,[Define if you don't want the nbd-server to fork()])
  71 else
  72   AC_MSG_RESULT([no])
  73 fi
  74
  75 AC_ARG_ENABLE(
  76   sdp,
  77   AC_HELP_STRING(--enable-sdp,Build a version of nbd-server with support for the Socket Direct Protocol (SDP). Requires you to build and install a kernel with the InfiniBand patches (default disabled)),
  78   [
  79     if test "x$enableval" = "xyes"; then
  80       AC_DEFINE(WITH_SDP, 1, [Define to 1 if you have and want support for the Socket Direct Protocol])
  81     fi
  82   ]
  83 )
  84
  85 AC_PROG_CC_C99
  86 AC_PROG_CPP
  87 AC_PROG_INSTALL
  88 AC_CANONICAL_HOST
  89 AC_C_BIGENDIAN
  90 AC_C_INLINE
  91 AC_C_CONST
  92 AC_CHECK_SIZEOF(unsigned short int)
  93 AC_CHECK_SIZEOF(unsigned int)
  94 AC_CHECK_SIZEOF(unsigned long int)
  95 AC_CHECK_SIZEOF(unsigned long long int)
  96 AC_CHECK_FUNCS([llseek alarm gethostbyname inet_ntoa memset socket strerror strstr])
  97 AC_FUNC_FORK
  98 AC_FUNC_SETVBUF_REVERSED
  99 AC_MSG_CHECKING(whether client should be built)
 100 case $host_os in
 101         linux*) NBD_CLIENT_NAME="nbd-client"
 102                 AC_MSG_RESULT(yes)
 103                 ;;
 104         *)      NBD_CLIENT_NAME=""
 105                 AC_MSG_RESULT(no)
 106                 ;;
 107 esac
 108 AC_SUBST(NBD_CLIENT_NAME)
 109 AC_SEARCH_LIBS(bind, socket,, AC_MSG_ERROR([Could not find an implementation of the bind() system call]))
 110 AC_SEARCH_LIBS(inet_ntoa, nsl,, AC_MSG_ERROR([Could not find an implementation of the inet_ntoa() system call]))
 111 AC_SEARCH_LIBS(daemon, resolv,, AC_MSG_ERROR([Could not find an implementation of the daemon() system call]))
 112 AC_CHECK_HEADERS([sys/mount.h],,,
 113 [[#include <sys/param.h>
 114 ]])
 115 AC_CHECK_HEADERS([arpa/inet.h fcntl.h netdb.h netinet/in.h sys/ioctl.h sys/socket.h syslog.h linux/types.h])
 116 AM_PATH_GLIB_2_0(2.6.0, [HAVE_GLIB=yes], AC_MSG_ERROR([Missing glib]))
 117 AC_HEADER_SYS_WAIT
 118 AC_TYPE_OFF_T
 119 AC_TYPE_PID_T
 120 nbd_server_CPPFLAGS=$nbd_server_CPPFLAGS" -DSYSCONFDIR='\"$sysconfdir\"'"
 121 AC_SUBST(nbd_server_CPPFLAGS)
 122 AC_CONFIG_HEADERS([config.h])
 123 AC_CONFIG_FILES([Makefile doc/Doxyfile man/Makefile man/nbd-client.8.sh man/nbd-server.5.sh man/nbd-server.1.sh])
 124 AC_OUTPUT
 125